Gnuplot: Change Density of dotted line in splot

Question

I am trying to plot a dotted line within an splot with the following code in Gnuplot 4.6 patchlevel 4:

set terminal "pdfcairo" enhanced dashed size 15,10
set pm3d map
set output "test.pdf"
splot 'map.dat' using 1:($2/1000):3 notitle, \
   'line1.dat' using 1:($2/1000):1 notitle with lines ls 2, \
   'line2.dat' using 1:($2/1000):1 notitle with lines ls 2
unset output

The heat map works and so does line1.dat. However, the second line appears mostly solid. The difference is that line1.dat has 70 entries and line2.dat has 900. The second line has a jump between two points and there it is dotted.

Does somebody know how I can change the dot density so that the whole line appears dotted. Changing the original data file is not an option.

Thank you for your help,

noes

EDIT:

One workaround I found is

splot 'line2.dat' every ...

but that can get unconvenient at the jump in the data.

Answer 1

The command (s)plot 'line.dat' with lines first plots the datapoints and then connects the datapoints using lines with the respective linestyle. If the datapoints are too close to each other, there is no place for some gaps when a dashed linestyle is used.

To display a dotted/dashed line, you can try to replace the points by a function or to reduce the number of points.

• Try dotted lines instead of dashed lines. Linestyle and linecolor can be set independently: splot 'line.dat' with lines ls 0 lc 2. 900 points might be too many for this approach.

• Fitting a function would work, but probably it is too difficult to find a suitable function.

• The every option reduces the number of points.

• Another possibility to reduce the number of points would be to interpolate the points using the smooth option. This requires a temporary file and works as follows:

  # [prepare plot]
  set samples 100
  set table "line2.dat.tmp"
  plot 'line2.dat' using 1:($2/1000) smooth mcsplines with lines ls 2 
  unset table
  
  set terminal "pdfcairo" enhanced dashed size 15,10
  set pm3d map
  set output "test.pdf"
  
  # [plot]
  splot 'map.dat' using 1:($2/1000):3 notitle, \
     'line1.dat' using 1:($2/1000):1 notitle with lines ls 2, \
     'line2.dat.tmp' using 1:2:1 notitle with lines ls 2
  
  unset output
  

In the [prepare plot] section a temporary file "line2.dat.tmp" is created which contains datapoints interpolating line2.dat. You have to play with set samples to get the right number of points. In the example we have 100 equidistant points instead of 900 points with different distances. The option smooth mcsplines preserves the monotonicity and convexity of the original data points, see help smooth mcsplines in a gnuplot shell.

In the [plot] section the original "lines2.dat" is replaced by the interpolated data.

This approach works if the original data is smooth enough so that replacing 900 points by 100 points does not skip important information. Maybe you want to plot both "lines2.dat" and "lines2.dat.tmp" in a single diagram to compare them.

Answer 2

User the every key-word, like this:

'line2.dat' every 20 using 1:($2/1000):1 notitle with lines ls 2