How I can know the equivalent DBPedia and Wikidata properties

Question

Could someone tell me how i can find the synonym property of DBPedia in Wikidata? for example, the property "name" in DBpedia is "label" in Wikidata. How I can find all the synonyms properties?

Answer 1

Further EDIT...

Querying DBpedia delivers a much larger set of equivalency mappings, obtained with a rather different yet very similar query.

PREFIX       owl:  <http://www.w3.org/2002/07/owl#>
PREFIX      rdfs:  <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?DBpediaProp ?itemLabel ?WikidataProp
WHERE
  {
    ?DBpediaProp  owl:equivalentProperty  ?WikidataProp .
                  FILTER ( CONTAINS ( str(?WikidataProp) , 'wikidata' ) ) .
    ?DBpediaProp  rdfs:label              ?itemLabel .
                  FILTER (lang(?itemLabel) = 'en')
  }
ORDER BY  ?DBpediaProp

EDIT springing from @Tom Morris' answer

This query can be run on the Wikidata endpoint, https://query.wikidata.org/. For completeness and increased portability, I include the PREFIX declarations (even though that endpoint auto-applies them). I also FILTER to get only the dbpedia equivalencies; you can strike that line to include equivalencies from schema.org and possibly other ontologies.

PREFIX       wdt:  <http://www.wikidata.org/prop/direct/>
PREFIX  wikibase:  <http://wikiba.se/ontology#>
PREFIX        bd:  <http://www.bigdata.com/rdf#>

SELECT ?WikidataProp ?itemLabel ?DBpediaProp
WHERE
  {
    ?WikidataProp  wdt:P1628  ?DBpediaProp .
    FILTER ( CONTAINS ( str(?DBpediaProp) , 'dbpedia' ) ) .
    SERVICE wikibase:label
      { bd:serviceParam  wikibase:language  "en" } .
  }

and you get (as of this writing) a whopping two such equivalencies.

My Original Answer

I do not believe a full cross-mapping is available anywhere, and for various reasons (not least being that these ontologies were not designed to be exactly synonymous), may never be.

That said, you might look at the DBpedia Mapping Wiki.

You can find much discussion....

• Wikidata/Notes/DBpedia and Wikidata
• Google Summer of Code 2013 Ideas: Wikidata Mappings
• Wikidata:Requests for comment/Can we reuse anything from DBpedia?
• DBpedia-based RDF dumps for Wikidata
• Wikidata through the Eyes of DBpedia

Answer 2

It doesn't appear to be well populated, but I'd expect DBpedia properties to show up in Wikidata's P1628 "Equivalent Property"

SELECT ?item ?itemLabel ?equivProp
WHERE
{
    ?item wdt:P1628 ?equivProp .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

example result:

item      itemLabel      equivProp
wd:P200   lake inflows   <http://dbpedia.org/ontology/inflow>