Error with changeSet in jenkins pipeline (Error:java.io.NotSerializableException: hudson.plugins.git.GitChangeSetList)

Question

I have this error:

java.io.NotSerializableException: hudson.plugins.git.GitChangeSetList

when ChangeSet!=null but the strange is that the error ocurred when updating this plugin: Pipeline Shared Groovy Libraries, before this work good, i use jenkins v 2.21 and pipeline 2.4 and my code is the next:

def changeLogSets = currentBuild.rawBuild.changeSets
for (int i = 0; i < changeLogSets.size(); i++) {
   def entries = changeLogSets[i].items
   for (int j = 0; j < entries.length; j++) {
        def entry = entries[j]
        echo "${entry.commitId} by ${entry.author} on ${new Date(entry.timestamp)}: ${entry.msg}"
        def files = new ArrayList(entry.affectedFiles)
        for (int k = 0; k < files.size(); k++) {
            def file = files[k]
            echo "  ${file.editType.name} ${file.path}"
        }
    }
}
changeLogSets= null

score 18 · Accepted Answer · answered Oct 27 '16 at 21:08

18

Jenkins jobs can be saved in mid execution, which requires them to be serialized. The contents of rawBuild cannot be serialized, so if you access this, you need to do so within a function that is prefaced with @NonCPS. E.g.:

showChangeLogs()

@NonCPS
def showChangeLogs() {
  def changeLogSets = currentBuild.rawBuild.changeSets
  for (int i = 0; i < changeLogSets.size(); i++) {
     def entries = changeLogSets[i].items
     for (int j = 0; j < entries.length; j++) {
          def entry = entries[j]
          echo "${entry.commitId} by ${entry.author} on ${new Date(entry.timestamp)}: ${entry.msg}"
          def files = new ArrayList(entry.affectedFiles)
          for (int k = 0; k < files.size(); k++) {
              def file = files[k]
              echo "  ${file.editType.name} ${file.path}"
          }
      }
  }
}

answered Oct 27 '16 at 21:08

BMitch

231,797
42
475
450

1

This does not seem to help if showChangeLogs is located inside a library that is imported into Jenkinsfile – gerasalus Dec 07 '17 at 19:08
@gerasalus I'm running into this issue in a shared library... Did you find a solution to it? – Marcello DeSales Sep 24 '18 at 20:09
Hi @MarcellodeSales, I just dealed with the same issue but using \@NonCPS annotation before the method in my shared libraries solved the exception. – Simone Marcato Nov 26 '19 at 11:43
@SimoneMarcato yeah that also solved our problems too! Thank you! – Marcello DeSales Nov 26 '19 at 17:47
further read here: https://github.com/jenkinsci/pipeline-plugin/blob/master/TUTORIAL.md#serializing-local-variables – flags Sep 01 '21 at 15:07

score 1 · Answer 2 · answered Oct 04 '21 at 03:34

Not exactly the same code, but the same problem can be caused if you don't declare local variables before their use. https://blog.csdn.net/liurizhou/article/details/88236397

So, additionally to adding "@NonCPS", you need to add 'def' before all local variables

score 0 · Answer 3 · answered Sep 02 '20 at 11:26

I want to provide another answer, piggybacking BMitch's answer. rawBuild method poses security issue and is blocked in Jenkinsfile. In newer versions currentBuild object exposes changeSets directly, so you can use the script like this

@NonCPS
def showChangeLogs() {
    def changeLogSets = currentBuild.changeSets
    for (int i = 0; i < changeLogSets.size(); i++) {
        def entries = changeLogSets[i].items
        for (int j = 0; j < entries.length; j++) {
            def entry = entries[j]
            echo "${entry.commitId} by ${entry.author} on ${new Date(entry.timestamp)}: ${entry.msg}"
            def files = new ArrayList(entry.affectedFiles)
            for (int k = 0; k < files.size(); k++) {
                def file = files[k]
                echo "${file.editType.name} ${file.path}"
            }
        }
    }
}

Error with changeSet in jenkins pipeline (Error:java.io.NotSerializableException: hudson.plugins.git.GitChangeSetList)

3 Answers3

Linked