How to redirect the app to location sensor settings in android using delphi

Question

I'm using Delphi 10.1 Berlin for developing android mobile application. And in that I need to check if the location sensor is not switched ON, then I need to redirect to the Location sensor Settings in android mobile. How can I able to implement using Delphi? I have seen example using JAVA but not found for Delphi. And Thanks in Advance.

Answer 1

You could try some code like the following. Here is a helper unit:

unit LocationU;

interface

function IsGPSProviderEnabled: Boolean;

function IsNetworkProviderEnabled: Boolean;

procedure LaunchLocationSettings;

implementation

uses
  System.SysUtils,
  Androidapi.Helpers,
  Androidapi.JNI.JavaTypes,
  Androidapi.JNI.GraphicsContentViewText,
  Androidapi.JNI.Location,
  Androidapi.JNI.Provider;

function IsProviderEnabled(const Provider: JString): Boolean;
var
  LocationManagerObj: JObject;
  LocationManager: JLocationManager;
begin
  LocationManagerObj := TAndroidHelper.Context.getSystemService(
    TJContext.JavaClass.LOCATION_SERVICE);
  LocationManager := TJLocationManager.Wrap(LocationManagerObj);
  Result := LocationManager.isProviderEnabled(Provider);
end;

function IsGPSProviderEnabled: Boolean;
begin
  Result := IsProviderEnabled(TJLocationManager.JavaClass.GPS_PROVIDER);
end;

function IsNetworkProviderEnabled: Boolean;
begin
  Result := IsProviderEnabled(TJLocationManager.JavaClass.NETWORK_PROVIDER);
end;

procedure LaunchLocationSettings;
begin
  TAndroidHelper.Activity.startActivity(
    TJIntent.JavaClass.init(TJSettings.JavaClass.ACTION_LOCATION_SOURCE_SETTINGS));
end;

end.

and here is some code that calls it:

uses
  FMX.Helpers.Android,
  Androidapi.Helpers,
  Androidapi.JNI.Widget,
  LocationU;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  if not IsGPSProviderEnabled and not IsNetworkProviderEnabled then
  begin
    CallInUiThread(
      procedure
      begin
        TJToast.JavaClass.makeText(
          TAndroidHelper.Context,
          StrToJCharSequence('Location services not enabled - launching settings'),
          TJToast.JavaClass.LENGTH_SHORT).show
      end);
    LaunchLocationSettings;
  end;
end;