Neo4j: Check condition between all consecutive relations in path

Question

I want to query all paths of arbitrary length

(a)-[:Relation*]->(b)

where for each pair (r1, r2) of consecutive relationships

()-[r1]->()-[r2]->()

a condition, say r2.foo > r1.foo, is met.

You can imagine foo being a timestamp and I only want to find paths where all steps are in chronological order.

What I currently have is this:

MATCH path = ()-[:Relationship*]->()
WITH rels(path) AS rels, path
WHERE reduce(acc = { inOrder: true, previous: rels[0] }, r IN tail(rels) |
    { inOrder: acc.inOrder AND r.foo > acc.previous.foo, previous: r }).inOrder
RETURN path

Now, this seems to work. However, I'm not sure if this is the most efficient query. Is there a better way to do it?

score 5 · Accepted Answer · answered Sep 12 '16 at 16:21

5

You can actually do it, by playing with the ALL predicate on the size of the relationships collection of the path, example :

MATCH p=(a:Cool)-[*]->(c) 
WHERE ALL ( x IN range(1, length(p)-1) WHERE (rels(p)[x]).i > (rels(p)[x-1]).i ) 
AND length(p) > 1
RETURN p

The i property in my query would be your relationship's timestamp property

Working example here :

http://console.neo4j.org/r/2bzo4m

answered Sep 12 '16 at 16:21

Christophe Willemsen

19,399
2
29
36

Thanks! I assume this is more efficient because `ALL` can short circuit? Small nitpick: Paths of length 1 are allowed as they are chronological by definition. – Kirill Rakhman Sep 12 '16 at 18:19
No it needs to traverse every path, if you need fast computations, a more deeper thought about your model depending on your use case is to be done, there is none model to fit them all ;-) – Christophe Willemsen Sep 12 '16 at 20:22
@KirillRakhman In Neo4j 3.1 the ALL will be applied as predicate and not as filter ;-) https://github.com/neo4j/neo4j/pull/7294 – Christophe Willemsen Sep 13 '16 at 12:03
Good to know. Is there a timeline for the 3.1 release? – Kirill Rakhman Sep 13 '16 at 12:11
2

RC1 soon, GA end of the year – Christophe Willemsen Sep 13 '16 at 12:16

Neo4j: Check condition between all consecutive relations in path

1 Answers1