How can I check the extension of a file using Perl?

Question

To my perl script, a file is passed as an arguement. The file can be a .txt file or a .zip file containing the .txt file.

I want to write code that looks something like this

if ($file is a zip) {

    unzip $file
    $file =~ s/zip$/txt/;
}

One way to check the extension is to do a split on . and then match the last result in the array (returned by split).

Is there some better way?

Are you sure you only want to check the extension? If you are hoping to test what type of file you are dealing with you would be better off checking the mime-type. Take a look at something like this: http://search.cpan.org/~pmison/File-Type-0.22/lib/File/Type.pm — totels, Oct 15 '10 at 08:30
Chiming in with support for @totels and a couple of the lower rep answers. I am surprised at how many think relying on the extension is either safe (`mv virus.exe hooters.jpg`) or robust (`mv some-huge-dossy-garbage.bin whatever.zip`). Assuming zip and catching errors or exploring the MIME type are the right answers given. Any solution using the extension is a mistake. — Ashley, Aug 09 '17 at 19:48

Dave Cross · Accepted Answer · 2016-03-15T15:07:09.617

14

You can use File::Basename for this.

#!/usr/bin/perl

use 5.010;
use strict;
use warnings;

use File::Basename;

my @exts = qw(.txt .zip);

while (my $file = <DATA>) {
  chomp $file;
  my ($name, $dir, $ext) = fileparse($file, @exts);

  given ($ext) {
    when ('.txt') {
      say "$file is a text file";
    }
    when ('.zip') {
      say "$file is a zip file";
    }
    default {
      say "$file is an unknown file type";
    }
  }
}

__DATA__
file.txt
file.zip
file.pl

Running this gives:

$ ./files 
file.txt is a text file
file.zip is a zip file
file.pl is an unknown file type

edited Mar 15 '16 at 15:07

answered Oct 15 '10 at 10:03

Dave Cross

68,119
3
51
97

`fileparse` returns the filename first, not the directory. – Hunter McMillen Mar 15 '16 at 15:05
You're right, of course, and I've fixed it. Weird that it went unnoticed for over five years. Thanks for pointing it out. – Dave Cross Mar 15 '16 at 15:07
No worries, your post solved my problem once I sorted out the order :) – Hunter McMillen Mar 15 '16 at 18:11
Better to add backslash before dot as `my @exts = qw(\.txt \.zip);`. Because the dot will be parse as a wildcard without backslash. – lylhw13 Apr 24 '22 at 15:12
@lylhw13: Good point. Maybe `my @exts = map { "\Q$_" } qw(.txt .zip)`. – Dave Cross Apr 25 '22 at 08:28

Alan Haggai Alavi · Answer 2 · 2010-10-15T09:09:39.567

12

Another solution is to make use of File::Type which determines the type of binary file.

use strict;
use warnings;

use File::Type;

my $file      = '/path/to/file.ext';
my $ft        = File::Type->new();
my $file_type = $ft->mime_type($file);

if ( $file_type eq 'application/octet-stream' ) {
    # possibly a text file
}
elsif ( $file_type eq 'application/zip' ) {
    # file is a zip archive
}

This way, you do not have to deal with missing/wrong extensions.

edited Oct 15 '10 at 09:09

answered Oct 15 '10 at 08:27

Alan Haggai Alavi

72,802
19
102
127

1

+1, but you should replace `my $file_type = File::Type->mime_type($file);` by `my $file_type = $ft->mime_type($file);` – Toto Oct 15 '10 at 08:45
2

`File::Type` works here, but in general does a pretty crappy job compared to [`File::LibMagic`](http://p3rl.org/File::LibMagic). – daxim Oct 15 '10 at 10:36
This is probably the best approach (either module) but the -T file test operator might be worth looking at too. – Nic Gibson Oct 15 '10 at 12:06
daxim: I will try `File::LibMagic`. Thank you. – Alan Haggai Alavi Oct 17 '10 at 16:30

eumiro · Answer 3 · 2010-10-15T08:05:26.690

9

How about checking the end of the filename?

if ($file =~ /\.zip$/i) {

and then:

use strict;
use Archive::Extract;

if ($file =~ /\.zip$/i) {
    my $ae = Archive::Extract->new(archive => $file);
    my $ok = $ae->extract();
    my $files = $ae->files();
}

more information here.

edited Oct 15 '10 at 08:05

answered Oct 15 '10 at 07:56

eumiro

207,213
34
299
261

score 4 · Answer 4 · answered Oct 15 '10 at 07:57

4

You can check the file extension using a regex match as:

if($file =~ /\.zip$/i) {
        # $file is a zip file 
}

answered Oct 15 '10 at 07:57

codaddict

445,704
82
492
529

score 3 · Answer 5 · answered Apr 04 '14 at 16:56

I know this question is several years old, but for anyone that comes here in the future, an easy way to break apart a file path into its constituent path, filename, basename and extension is as follows.

use File::Basename;

my $filepath = '/foo/bar.txt';

my ($basename, $parentdir, $extension) = fileparse($filepath, qr/\.[^.]*$/);
my $filename = $basename . $extension;

You can test it's results with the following.

my @test_paths = (
    '/foo/bar/fish.wibble',
    '/foo/bar/fish.',
    '/foo/bar/fish.asdf.d',
    '/foo/bar/fish.wibble.',
    '/fish.wibble',
    'fish.wibble',
);

foreach my $this_path (@test_paths) {
    print "Current path: $this_path\n";
    my ($this_basename, $parentdir, $extension) = fileparse($this_path, qr/\.[^.]*$/);
    my $this_filename = $this_basename . $extension;

    foreach my $var (qw/$parentdir $this_filename $this_basename $extension/) {
        print "$var = '" . eval($var) . "'\n";
    }

    print "\n\n";
}

Hope this helps.

Eugene Yarmash · Answer 6 · 2010-10-15T13:13:46.583

2

Why rely on file extension? Just try to unzip and use appropriate exception handling:

eval {
    # try to unzip the file
};

if ($@) {
    # not a zip file
}

edited Oct 15 '10 at 13:13

answered Oct 15 '10 at 08:23

Eugene Yarmash

142,882
41
325
378

What if you don't have 'unzip' installed on your system, or if it is not in your path? – Prakash K Oct 15 '10 at 13:03
@Prakash: `unzip` is supposed to be a perl function. Nevermind, replaced with comments :) – Eugene Yarmash Oct 15 '10 at 13:16

score 0 · Answer 7 · answered Nov 22 '19 at 08:30

Maybe a little bit late but it could be used as an alternative reference:

sub unzip_all {
     my $director = shift;
     opendir my $DIRH, "$director" or die;
     my @files = readdir $DIRH;
     foreach my $file (@files){
              my $type = `file $director/$file`; 
              if ($type =~ m/gzip compressed data/){
                      system "gunzip $director/$file";
              }
      }       
      close $DIRH;
      return;
}

Here is possible to use linux file executing it from perl by the use of backticks(``). You area able to pass the path of your folder and evaluate if exists a file that is classified by file as gzip compressed.

score 0 · Answer 8 · answered Apr 06 '22 at 23:03

If you do not mind using a perl module, you can use Module::Generic::File, such as:

use Module::Generic::File qw( file );
my $f = file( '/some/where/file.zip' );
if( $f->extension eq 'zip' )
{
    # do something
}

Module::Generic::File has a lot of features to handle and manipulate a file.

How can I check the extension of a file using Perl?

8 Answers8

Linked