4

Suppose a function defined like this:

def composition(text : String, k : Int32) : Array(String)
  kmers = Array(String).new
  (0 .. text.size - k).each do |i|
    kmers << text[i, k]
    yield text[i, k]
  end
  return kmers
end

How do I check if the block argument is given inside the function? If the block argument is given, kmers will be yielded. If not given, kmers will be returned as an array of strings.

Wen-Bin Luo
  • 147
  • 1
  • 15

2 Answers2

10

Such a check is impossible, because a method accepting a block (using yield anywhere) already has a signature requiring it. But that also means that you don't need the check. If you want to make it optional, just make 2 methods like this:

# if you want to be explicit (makes no difference, this method requires a block):
# def composition(text : String, k : Int32, &block)
def composition(text : String, k : Int32)
  (0 .. text.size - k).each do |i|
    yield text[i, k]
  end
end

# and the non block option
def composition(text : String, k : Int32) : Array(String)
  kmers = [] of String
  composition(text, k) do |s|
    kmers << s
  end
  return kmers
end
rogerdpack
  • 62,887
  • 36
  • 269
  • 388
Oleh Prypin
  • 33,184
  • 10
  • 89
  • 99
  • 3
    That handles the OP's use case, but there is still the question as to whether or not it is possible to determine whether or not a block has been passed. Is there? I think not, because calling a function expecting a block without a block results in a compile time error; so there is no way to even rescue the exception at runtime. – Keith Bennett Aug 08 '17 at 08:23
2

In your specific situation, I would recommend Oleh's answer. However, here's a more general solution that lets you determine whether a block has been passed:

def composition(text, k, &block : String ->)
  composition(text, k, block)
end

def composition(text, k, block : (String ->)? = nil)
  kmers = [] of String
  (0 .. text.size - k).each do |i|
    s = text[i, k]
    if block
      block.call s
    else
      kmers << s
    end
  end
  kmers
end

(For more information on Proc syntax, see https://crystal-lang.org/reference/syntax_and_semantics/type_grammar.html#proc)

fn control option
  • 1,745
  • 6
  • 18
  • Following is another working example: https://forum.crystal-lang.org/t/what-is-the-equivalent-of-ruby-block-given/5059/3?u=zw963 – zw963 Nov 02 '22 at 05:53