Get time-stamp of a file and check is this today or not

Question

In Perl, how can I get time-stamp of a file and check is this today or not?

Answer 1

I would (probably) use -M:

http://perldoc.perl.org/functions/-X.html

-M Script start time minus file modification time, in days.

This means you can do:

if ( -M $filename < 1 ) { 
    #if file is less than a day old
}

This of course, only applies relative to script start, rather than right now so isn't suitable for long running scripts.

Answer 2

If helps if you show us exactly what you have tried and what problems you are having.

You can use File::stat to get information about a file.

use File::stat;
my $stat = stat($file);

You can get three different timestamps by calling three different methods on the $stat object.

my $ctime = $stat->ctime; # inode change time
my $atime = $stat->atime; # last access time
my $mtime = $stat->mtime; # last modification time

I think you probably want $mtime, but I can't be sure. Each of these variables contain the time as the number of seconds since your system's epoch (almost certainly 00:00 on 1st Jan 1970).

You can convert these epoch values into useful objects using Time::Piece.

use Time::Piece;
my $file_date = localtime($mtime);

And you can compare that with the current date.

if ($file_date->date eq localtime->date) {
  # file was created today
}

Answer 3

1. Read about File::stat and get timestamp of file. How do I get a file's last modified time in Perl?

use File::stat;
 # we don't need anything but mtime
 # my ($dev, $ino, $mode, $nlink, $uid, $gid, $rdev, $size,
 #    $atime, $mtime, $ctime, $blksize, $blocks) = stat($filename);
my $ts = stat($filename)->mtime;
print "ts:$ts";
print " date/time " . localtime($ts) . "\n";

ts:1469028287 date/time Wed Jul 20 16:24:47 2016

Oh look. mtime is a big number. How many . . minutes / hours / days / years is that ? (dc is a command-line calculator.)

$ dc
1469028287
60/p
24483804
60/p
408063
24/p
17002
356.25/p
47

47 years. (gained/lost some time up there with the integer division using dc). Now (Mon 8 Aug 10:58ish 2016) - 46(where 46 =ishahem= 47) years = 1/1/1970 00:00:00 = the unix date/time stamp epoch.

2. Read about localtime, get 'now' time, get times from midnight to midnight for today. http://perldoc.perl.org/functions/localtime.html http://www.perlhowto.com/working_with_date_time How do I use Perl's localtime with print to get the timestamp? Note the value of year from localtime is 116 (116 years since 1900). Note the value of month from localtime is 7 (7 for August. yes because 0 = January, 1 = Feb, e.t.c.).

# localtime returns array or string depending on context.
my $time = localtime;
my @time = localtime;
print "time:$time\n";    
print "time array: " . join (":", (@time)) . "\n";

my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime;
use Time::Local;
my $btime = timelocal(0,0,0,$mday,$mon,$year);
my $etime = timelocal(59,59,23,$mday,$mon,$year);
print "btime:$btime " . localtime($btime) . " etime:$etime " . localtime($etime) . "\n";
print "year:$year\n";

time:Mon Aug  8 11:40:33 2016
time array: 33:40:11:8:7:116:1:220:1
btime:1470610800 Mon Aug  8 00:00:00 2016 etime:1470697199 Mon Aug  8 23:59:59 2016
year:116

3. Check file timestamp is between the midnight times. Check all the stuffs.

if (($ts >= $btime) && ($ts <= $etime)) {
   print "File time $ts (".localtime($ts).") is TODAY.\n";
} else {
   print "File time $ts (".localtime($ts).") is NOT today.\n";
   if ($ts < $btime) {
       print "File is BEFORE today. $ts < $btime\n";
   } elsif ($ts > $etime) {
       print "File is in FUTURE. $ts > $etime\n";
   } else {
       print "KERBOOM.\n"
   }
}

Answer 4

One of the ways how to do it condensed to a one-liner: perl -e '$f = shift; printf "file %s updated at %s\n", $f, scalar localtime((stat $f)[9])' file.