How to split a string containing {hello}{world} curley brackets but keep the brackets (vb.net)

Question

I'm trying to find a way of splitting a string that contains 2 {}{} brackets but after it's split it keeps the brackets.

Before word = {XXXX}{XXXX}

After

• Word(1) = {XXXX}

• word(2) = {XXXX}

I tried using split but this always removes the }{ which I want to keep. Somebody get me out of my misery!! I'm using vb.net.

Dim word As String = "{hello}{world}" 
Dim wordArr As String() = word.Split("}")

Answer 1

You can also try to use regular expressions.

    Dim pattern As New Regex("(?<Word1>\{\w+\})(?<Word2>\{\w+\})")
    Dim match = pattern.Match("{Hello}{World}")

    Dim word1 = match.Groups("Word1").Value
    Dim word2 = match.Groups("Word2").Value

Answer 2

This will work:

Dim word As String = "{hello}{world}"
    Dim wordArr As String() = word.Split({"}"}, StringSplitOptions.RemoveEmptyEntries)
    Dim lst1 As New List(Of String)
    For Each l In wordArr
        lst1.Add(l & "}")
    Next
    wordArr = lst1.ToArray

Answer 3

Here is a Linq way:

    Dim brace As Char = "}"c
    Dim output As String() = (From s In input.Split(brace) 
        Where s <> String.Empty 
        Select s + brace).ToArray()

Answer 4

Here's another option using an iterator:

Public Iterator Function SplitAfter(input As String, delim As Char) As IEnumerable(Of String)
    Dim sb As StringBuilder = New StringBuilder(input.Length)
    For Each c As Char In input
        sb.Append(c)
        If c = delim Then
            Yield sb.ToString()
            sb.Clear()
        End If
    Next
    If sb.Length > 0 Then
        Yield sb.ToString()
    End If
End Function

Dim word As String = "{hello}{world}"
Dim wordArr As String() = SplitAfter(word, "}"c).ToArray()
For Each w As String In wordArr
    Console.WriteLine(w)
Next

Output:

{hello}
{world}