STOSB instruction not storing byte when run from a bootloader

Question

After making a small bootloader to teach myself assembly language, I noticed that the stosb instruction does not seem to be work. I compressed the issue to a minimal example:

BITS 16

start:
mov ax, 07C0h       
add ax, 288     
mov ss, ax
mov sp, 4096

mov ax, 07C0h       
mov ds, ax ;setting up stack

mov al, 'j'
mov di, buffer
stosb

mov si, buffer
jmp loops

loops:
mov ah, 0Eh
lodsb
cmp al, 0
je done
int 10h
jmp loops

done:
hlt

buffer times 64 db 0

times 510-($-$$) db 0   ; Pad remainder of boot sector with 0s
dw 0xAA55

When this bootloader is run it should store the letter j into a buffer, and then print that buffer to the display. The output should be:

j

When run it doesn't seem to print anything. What is the problem, and how can I fix it?

Does the ES register have to be initialized/set up for this to work? — zerotwo77, Jul 07 '16 at 16:36
RTM: `stosb` refers to `ES` by default unless you provide a segment override. — Weather Vane, Jul 07 '16 at 16:37
Yes, the STOSB instruction stores data at [ES:DI] by default. See an [instruction set reference](http://x86.renejeschke.de/) for information on [STOSB](http://x86.renejeschke.de/html/file_module_x86_id_306.html) — Michael Petch, Jul 07 '16 at 16:37
You can set it to the same value you are using for DS which is 0x7c0 — Michael Petch, Jul 07 '16 at 16:38
This is more understandable in the context of the `movsb` instruction in the same family, which can move data between segments - the simpler instructions follow the same pattern. — Weather Vane, Jul 07 '16 at 16:40
After setting ES to 0x7c0 everything seems to work! Thanks for the help! — zerotwo77, Jul 07 '16 at 16:41
@MichaelPetch Would you like to write an answer to this question so that it can be accepted? — user1354557, Jul 07 '16 at 19:01
@user1354557 I think the question has been asked in other forms (although not an exact duplicate) on SO. Anyone who wishes to answer it can be my guest. — Michael Petch, Jul 07 '16 at 19:06
@zerotwo77 You must also set the direction flag (CLD or STD) before string instruction execution! — GJ., Jul 07 '16 at 22:03

user1354557 · Accepted Answer · 2016-07-11T14:37:54.907

The solution was given by Michael Petch, Weather Vane, Jim Mischel, and GJ in the comments. To elaborate:

The STOSB instruction implicitly stores data to [ES:DI], whereas the LODSB instruction implicitly loads data from [DS:SI]. You use STOSB to write to buffer and LODSB to read from buffer. However, you set the DS segment register but not ES. Therefore, you are not storing the 'j' character to the same location that you are reading from.

The solution is just to set ES along with DS:

mov ax, 07C0h       
mov ds, ax
mov es, ax

Note: You may also want to explicitly clear the direction flag before using string instructions (e.g. LODSB, STOSB) in your code. You can do this with the CLD instruction. The BIOS would most likely leave the direction flag cleared before handing off to the bootsector (which is why it worked for you without the CLD), but to be absolutely sure, you should clear the flag yourself.

IIRC, it's not safe to assume anything about the direction flag. In general, code as defensively as possible in a bootloader, because real-world PC BIOSes exist with nearly every bug imaginable. I haven't written bootloader code myself, but that's what I've read. — Peter Cordes, Jul 11 '16 at 18:26

STOSB instruction not storing byte when run from a bootloader

1 Answers1