How to get image and track name of Spotify app using AppleScriptObjC

Question

I'm creating a new cocoa app using the Cocoa Applescript in Xcode and i want to get the track details from spotify as to render the image in my app. I created a simple window with two button next and prev with 2 text labels for artist name and track name. I managed to get the track details and the image url from Script Editor, however i cannot somehow store it in Xcode.

The next and prev button work but nothing is showing at the labels and the image (ImageView).

p/s : I linked all the outlet to xib.

script AppDelegate
property parent : class "NSObject"

-- IBOutlets
property theWindow : missing value
property labelOne : missing value
property labelTwo : missing value
property buttonNext : missing value
property buttonPrev : missing value
property imageOne : missing value
property ourWeb : missing value

property artist1 : "default1"
property artist2 : "default2"
property url1 : "defaulturl"

tell application "spotify"
    set url1 to get artwork url of current track as string
    tell artist1 to get artist of current track as string
    set track1 to get name of current track
    labelOne's setStringValue_(artist1)
end tell

on nextClicked_(sender)
    tell application "spotify" to next track
end nextClicked_

on prevClicked_(sender)
    tell application "spotify" to previous track
end prevClicked_
end script

I hope someone can help me. This is actually a test app for learning applescript with xcode. Thanks in advance!

Ron Reuter · Accepted Answer · 2016-06-08T03:19:10.657

1

Change tell artist1 to get artist... to set artist1 to get artist...

Now that artist1 has a valid string value, and IF it is wired-up to the NSTextField properly, it should show up in the text field. You can also simplify your Spotify code like so:

tell application "Spotify"
    tell current track
        set name1 to name
        set artist1 to artist
        set url1 to artwork url
    end tell
end tell

labelOne's setStringValue_(artist1)

edited Jun 08 '16 at 03:19

answered Jun 08 '16 at 00:30

Ron Reuter

1,287
1
8
14

thanks Ron Reuter. Now i need to figure out how to put the image. Thanks again! – Muhammad Syahman Jun 08 '16 at 13:17

score 0 · Answer 2 · answered Jun 09 '16 at 12:37

Here's a way to transform the artwork url string into an NSImage for display in the UI, using AppleScript-ObjectiveC syntax. imgAlbumCover is the NSImageView that will display the image.

use framework "Foundation"
use framework "AppKit"

tell application "spotify"
    tell current track
        set tArtworkURL to artwork url
    end
end tell

set coverURL to current application's NSURL's  URLWithString:tArtworkURL
set imageData to current application's NSData's dataWithContentsOfURL:coverURL
set coverImage to current application's NSImage's alloc()'s initWithData:imageData

set imgAlbumCover's image to coverImage

Remember to enable App Transport Security in Info.plist so you can make the http:// request. (NSAppTransportSecurity -> NSAllowsArbitraryLoads)

Thanks Ron for the code! I used this, 'set theURL to current application's NSURL's URLWithString_(url1) set theImage to current application's NSImage's alloc's initWithContentsOfURL_(theURL)' — Muhammad Syahman, Jun 10 '16 at 13:47

How to get image and track name of Spotify app using AppleScriptObjC

2 Answers2