AWK FNR==NR on an Empty File

Question

I am running the following command which works great as long as their is content in the first file:

awk -F, 'FNR==NR {a[tolower($1)]++; next} !a[tolower($1)]' OutSideSyncUsers.csv NewUsers.csv

If the first file is empty, the command doesnt work. I found online this reference:

all the programs that use the two-files idiom will not work correctly if the first file is empty (in that case, awk will execute the actions associated to NR==FNR while reading the second file). To correct that, you can reinforce the NR==FNR condition by adding a test that checks that also FILENAME equals ARGV[1].

Im not sure I understand how (or where) in the query to add the test check equals ARGV[1]

Any help would be apperciated

anubhava · Accepted Answer · 2016-05-03T19:26:45.597

6

You can use this additional conditions like this:

awk -F, 'ARGV[1] == FILENAME{a[tolower($1)]++; next} !a[tolower($1)]' OutSideSyncUsers.csv NewUsers.csv

Additional condition ARGV[1]==FILENAME ensures that first block only executes for the first file only in argument list. When first file is empty then it will just skip the first block. This way you make sure 2nd block !a[tolower($1)] is always executing on 2nd file in argument list.

edited May 03 '16 at 19:26

answered May 03 '16 at 19:17

anubhava

761,203
64
569
643

1

awesome, your explanation is exactly the info I was looking for – moore1emu May 03 '16 at 19:19
1

I've added explanation in my answer. `FILENAME` is already set by `awk` to the current input filename. – anubhava May 03 '16 at 19:20
so does this code still work if the second file is ever blank? or will that cause a problem? – moore1emu May 03 '16 at 19:30
If 2nd file is empty, do you want all lines to be printed from 1st file or not print anything at all? – anubhava May 03 '16 at 19:34
1

To answer your question, yes this command works fine even if 2nd file is blank and it will just skip printing anything. – anubhava May 03 '16 at 19:37
so if the first and second file is empty, i would just want it to create a blank file. because I only want the differences from the second file – moore1emu May 03 '16 at 19:38
Yes if both files are empty or just the 2nd file is empty then output will blank. – anubhava May 03 '16 at 19:43

Ed Morton · Answer 2 · 2022-10-07T13:32:29.203

With GNU awk use ARGIND:

awk -F, '{k=tolower($1)} ARGIND==1{a[k]; next} !(k in a)' OutSideSyncUsers.csv NewUsers.csv

with other awks an approximation is:

awk -F, '{k=tolower($1)} FILENAME==ARGV[1]{a[k]; next} !(k in a)' OutSideSyncUsers.csv NewUsers.csv

but that fails if/when you are parsing the same file twice so then you can set variables between the files:

awk -F, '{k=tolower($1)} !f{a[k]; next} !(k in a)' OutSideSyncUsers.csv f=1 NewUsers.csv

AWK FNR==NR on an Empty File

2 Answers2

Linked