How to product and sum the values of two different nodes of a different complex element using xslt?

Question

My XML is

<root> <source> <item> <id>111</id> <qty>2</qty> </item> <item> <id>222</id> <qty>1</qty> </item> <item> <id>333</id> <qty>4</qty> </item> </source> <target> <record> <id>111</id> <price>1000</price> </record> <record> <id>333</id> <price>500</price> </record> </target> </root>

Now i need to match the id element of source/item and target/record if it matches i need to product the

source/item/qty * target/record/price

Once the product is done for all the matching case i should sum all product value and should get the result as

4000 i.e (sum(qty * price) of all matching elements.)

How to achieve this kindly help me on this , thanks in advance

score 0 · Answer 1 · answered Apr 23 '16 at 19:01

0

In XSLT 2.0, you can do:

<xsl:key name="target" match="record" use="id" />

<xsl:template match="/root">
    <result>
        <xsl:value-of select="sum(source/item[key('target', id)]/(qty * key('target', id)/price))"/>
    </result>
</xsl:template>

answered Apr 23 '16 at 19:01

michael.hor257k

113,275
6
33
51

thanks for your answer, We are using xslt 1.0 sinc our framework support that only. – Satiz Apr 23 '16 at 19:41
Then why did you tag your question as XSLT 2.0? – michael.hor257k Apr 23 '16 at 21:18
I thought people who knows 2.0 can also help me in solving this issue. – Satiz Apr 23 '16 at 21:20
[A tag is a word or phrase that describes the topic of the question.](http://stackoverflow.com/help/tagging) It is not meant to describe people that you think can help you. Thank you for wasting my time. – michael.hor257k Apr 23 '16 at 21:25

score 0 · Accepted Answer · edited May 23 '17 at 11:59

I have modified this answer from Dimitre Novatchev to suit your requirement. The code is as follows:

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes" omit-xml-declaration="yes"/>

    <xsl:key name="target" match="record" use="id" />

    <xsl:template match="/">
        <xsl:call-template name="sumProducts">
            <!-- get only sources with respective equivalent targets -->
            <xsl:with-param name="pList" select="*/*/item[key('target', id)]"/>
            <!-- a list of target records -->
            <xsl:with-param name="pList2" select="*/*/record"/>
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="sumProducts">
        <xsl:param name="pList"/>
        <xsl:param name="pList2"/>
        <xsl:param name="pAccum" select="0"/>

        <xsl:choose>
            <xsl:when test="$pList">
                <xsl:variable name="vHead" select="$pList[1]"/>
                <xsl:variable name="vHead2" select="$pList2"/>

                <xsl:call-template name="sumProducts">
                    <xsl:with-param name="pList" select="$pList[position() > 1]"/>
                    <xsl:with-param name="pList2" select="$pList2"/>
                    <xsl:with-param name="pAccum"
                        select="$pAccum + $vHead/qty * $vHead2[id = $vHead/id]/price"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$pAccum"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

& Dimitre thank you so much for your answer it was helpful – Satiz May 02 '16 at 05:39 — Satiz, May 02 '16 at 05:39

How to product and sum the values of two different nodes of a different complex element using xslt?

2 Answers2