Unknown memory leak form delphi xe8

Question

I created a simple application with a button on a form Tform1 which is used to create another form Tform2. Form2 contains a toolbar with 2 buttons at each corner and a label with a tabcontrol below it. I keep getting this memory leak below. Im sure i created and destroyed the forms correctly.

Screenshot of error

program Project1;

uses
  System.StartUpCopy,
  FMX.Forms,
  Unit1 in 'Unit1.pas' {Form1},
  Unit2 in 'Unit2.pas' {Form2};

{$R *.res}

begin
   ReportMemoryLeaksOnShutdown := True;
  Application.Initialize;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end.

here is the form1 that creates the form2

unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs,
  FMX.Controls.Presentation, FMX.StdCtrls, Unit2;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

procedure TForm1.Button1Click(Sender: TObject);
begin
        Hide;
        Application.CreateForm(TForm2, Form2);
        Form2.Show;
        Form2.WindowState := TWindowState.wsMaximized;
end;

end.

Form 2 with the toolbar and tabcontrol

Form2 layout pic

unit Unit2;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMX.StdCtrls,
  FMX.TabControl, FMX.Controls.Presentation;

type
  TForm2 = class(TForm)
    ToolBar1: TToolBar;
    Button1: TButton;
    TabControl1: TTabControl;
    TabItem1: TTabItem;
    TabItem2: TTabItem;
    Label1: TLabel;
    Button2: TButton;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form2: TForm2;

implementation

{$R *.fmx}

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := TCloseAction.caFree;
  // ShowMessage('Form Freed now closing whole application') ;
  Application.MainForm.Close;
end;

end.

Answer 1

As I said in the comments, I can not reproduce the memory leak reports with the code you have shown. But maybe you are chasing the wrong goose, so I'll take a chance with some guesswork.

You never explained why you are treating Form1 the way you are, but I got this strange feeling that it may be a login form. If that is the case I would do it as follows:

Project1.dpr

program Project1;

uses
  System.StartUpCopy,
  FMX.Forms,
  Unit1 in 'Unit1.pas' {Form1},
  Unit2 in 'Unit2.pas' {Form2},
  System.UITypes;  // for the modal result

{$R *.res}

begin
  ReportMemoryLeaksOnShutdown := True;
  Application.Initialize;

  Form1 := TForm1.Create(Application);
  try
  if Form1.ShowModal <> System.UITypes.mrOK then
    Exit;
  finally
    Form1.Free;
  end;

  Application.CreateForm(TForm2, Form2);
  Application.Run;
end.

Note that Form1 is not created with Application.CreateForm. The reason is that the first form created with Application.CreateForm becomes the main form of the application and closing it would close the application. Instead we let Form2, where the main UI is, become the main form so we can free Form1 which is not needed after login.

Now we also need to set the modal result of the login form (Form1), for example (but you will want to make it more secure):

procedure TForm1.Button1Click(Sender: TObject);
begin
  if (Edit1.Text = 'User') and (Edit2.Text = 'pass') then
    modalresult := System.UITypes.mrOK;
end;

Let me know if this is not at all what you are looking for and I'll delete.