ORA-29494: invalid state for run task error with DBMS_PARALLEL_EXECUTE

Question

I am running a PL/SQL procedure with DBMS_PARALLEL_EXECUTE. I get stuck with ORA-29494: invalid state for run task error. My code is as below:

Below is the sample output for the DBMS_OUTPUT statement:

PROCESSING 5743 PROCESSING 5744

When I individually run the create task, chunk task and run task with input rowid from the user_parallel_execute_chunks, It works just fine for individual chunks. Also without loop, the task runs for all the chunks and ends with an error saying chunk_not_found. To handle that I used the loop, But I am not able to make it work

CREATE OR REPLACE PROCEDURE code_parse_wrapper AS
l_sql_stmt VARCHAR2(32767);
l_chunk_id NUMBER;
l_start_rowid ROWID;
l_end_rowid ROWID;
l_any_rows BOOLEAN;
l_try NUMBER;
l_status NUMBER;
l_stmt CLOB;
V_CHUNK_ID NUMBER;
V_STATUS VARCHAR2(30);
BEGIN
BEGIN

dbms_parallel_execute.drop_task(task_name => 'parallel_processing');
DBMS_OUTPUT.PUT_LINE('TASK DROPPED');
END;    
BEGIN
dbms_parallel_execute.create_task(task_name => 'parallel_processing');
DBMS_OUTPUT.PUT_LINE('TASK CREATED');
END;


-- Create Chunks

BEGIN
dbms_parallel_execute.create_chunks_by_rowid
(
    'parallel_processing',
    'SchemaName',
    'ORDER_DETAIL',
    FALSE,
    50000
); 
END;

BEGIN   
LOOP
    dbms_parallel_execute.get_rowid_chunk
    (
        task_name => 'parallel_processing',
        chunk_id => l_chunk_id,
        start_rowid => l_start_rowid,
        end_rowid => l_end_rowid,
        any_rows => l_any_rows
    );
  select STATUS INTO V_STATUS from user_parallel_execute_tasks where task_name =  'parallel_processing';
    DBMS_OUTPUT.PUT_LINE(V_STATUS);

    l_sql_stmt := ' begin CODE_PARSE6_AK( :start_id, :end_id ); end;';
    DBMS_OUTPUT.PUT_LINE(l_chunk_id);
--    DBMS_OUTPUT.PUT_LINE(l_sql_stmt);
 IF (l_any_rows = false) THEN 
 EXIT;
  END IF;   

BEGIN
    -- Get next unassigned chunk.
    --  EXECUTE IMMEDIATE 'l_sql_stmt USING l_start_rowid, l_end_rowid'; 

        dbms_parallel_execute.run_task('parallel_processing',
                                                     l_sql_stmt,
                                                     DBMS_SQL.NATIVE,
                                                    parallel_level => 10
                                                  );

                                                  l_try := 0;
 l_status := dbms_parallel_execute.task_status('parallel_processing');

 WHILE(l_try < 2 and l_status != dbms_parallel_execute.finished)     LOOP
             l_try := l_try + 1;
             dbms_parallel_execute.resume_task('parallel_processing');
             l_status :=    dbms_parallel_execute.task_status('parallel_processing'); 


    dbms_parallel_execute.set_chunk_status
        (
            task_name => 'parallel_processing',
            chunk_id => l_chunk_id,
            status => dbms_parallel_execute.processed
        ); 

        END LOOP;

    EXCEPTION

        WHEN OTHERS THEN
            -- Record chunk error.
            dbms_parallel_execute.set_chunk_status
            (
                task_name => 'parallel_processing',
                chunk_id => l_chunk_id,
                status => dbms_parallel_execute.processed_with_error,
                err_num => SQLCODE,
                err_msg => SQLERRM
            );
            END;

 COMMIT;

END LOOP;
END;


END;

pahariayogi · Answer 1 · 2016-10-22T20:46:31.547

Note sure why are doing get_rowid_chunk, set_chunk_status etc. I would use by_row => TRUE with create_chunks_by_rowid.

I think, you can use a simpler, cleaner piece of code here ... I have been using it for years without any issues. One can reuse this mostly by changing DML in l_sql_stmt.

DECLARE
  l_task     VARCHAR2(30) := 'parallel_processing';
  l_sql_stmt VARCHAR2(32767);
  l_try      NUMBER;
  l_status   NUMBER;
BEGIN
  DBMS_PARALLEL_EXECUTE.create_task (task_name => l_task);

  DBMS_PARALLEL_EXECUTE.create_chunks_by_rowid(task_name   => l_task,
                                               table_owner => 'SCHEMANAME',
                                               table_name  => 'ORDER_DETAIL',
                                               by_row      => TRUE,
                                               chunk_size  => 10000);

  l_sql_stmt := 'begin CODE_PARSE6_AK( :start_id, :end_id ); end;';

  DBMS_PARALLEL_EXECUTE.run_task(task_name      => l_task,
                                 sql_stmt       => l_sql_stmt,
                                 language_flag  => DBMS_SQL.NATIVE,
                                 parallel_level => 10);

  -- If there is error, RESUME it for at most 2 times.
  l_try := 0;
  l_status := DBMS_PARALLEL_EXECUTE.task_status(l_task);
  WHILE(l_try < 2 and l_status != DBMS_PARALLEL_EXECUTE.FINISHED) 
  Loop
    l_try := l_try + 1;
    DBMS_PARALLEL_EXECUTE.resume_task(l_task);
    l_status := DBMS_PARALLEL_EXECUTE.task_status(l_task);
  END LOOP;

  DBMS_PARALLEL_EXECUTE.drop_task(l_task);
END;
/

ORA-29494: invalid state for run task error with DBMS_PARALLEL_EXECUTE

1 Answers1