Reply to active email - add text, send, delete & then open next mail item

Question

I want after replying to the active mail to delete that active mail then open the next item in the folder.

I found this answer, added 'olItem.Delete' but need the 'open next mail item'.

Sub ReplyMSG()
    Dim olItem As Outlook.MailItem
    Dim olReply As MailItem ' Reply
    Dim olRecip As Recipient ' Add Recipient
    Dim objInsp As Outlook.Inspector
    Dim objActionsMenu As Office.CommandBarControl

    For Each olItem In Application.ActiveExplorer.Selection
        Set olReply = olItem.Reply
        olReply.HTMLBody = "Thank you!" & vbCrLf & olReply.HTMLBody
        olReply.Send objInsp.CommandBars.ExecuteMso(478)
        objActionsMenu.Execute
    Next olItem
End Sub

Answer 1

You should process Activeinspector.CurrentItem not the selection. The code in that link will behave differently than expected if you, say leave mail open, make other selections in the explorer window, come back to the original mail which is now not selected.

To go to the next item after deleting, try simulating a click on the delete button.

Both these ideas are demonstrated in this answer.

Sub SetEditMode()
Dim myItem As Outlook.MailItem
Dim objInsp As Outlook.Inspector
Dim objActionsMenu As Office.CommandBarControl
Dim olNewMailItem As Outlook.MailItem

On Error Resume Next ' Bad coding do not do this

Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
        Set myItem = ActiveExplorer.Selection.Item(1)
        myItem.Display
    Case "Inspector"
        Set myItem = ActiveInspector.CurrentItem
    Case Else
End Select
If myItem Is Nothing Then GoTo ExitProc
'edit mode
Set objInsp = ActiveInspector
objInsp.CommandBars.ExecuteMso ("EditMessage")
objActionsMenu.Execute

ExitProc:
End Sub

Use this idea to refer to your mail.

Set myItem = ActiveInspector.CurrentItem

Use this idea to click a button.

objInsp.CommandBars.ExecuteMso ("EditMessage")

EditMessage is an Mso ID / Control ID. You can find the Mso ID for the Delete button by hovering over the icon where you add buttons to the Quick Access toolbar or a ribbon.

You can download a list here 2007 Office System Document: Lists of Control IDs

Edit: 2016-02-22

Control ID may not work as I thought. Use the hover technique.

Sub Reply_ExecuteMso_DeleteOriginal()
'
' ** NOT working as intended **
'
' Simulating clicking the delete button is too fast
'  Must slow down with a MsgBox
'
' Now it is the same as clicking delete manually
'
Dim olItem As Object
Dim olReply As mailItem
Dim objInsp As Inspector

Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
        Set olItem = ActiveExplorer.Selection.Item(1)
        olItem.Display
    Case "Inspector"
        Set olItem = ActiveInspector.currentItem
End Select

If olItem Is Nothing Then GoTo ExitProc

If olItem.Class = olMail Then

    Set olReply = olItem.Reply
    olReply.Display

    olReply.HTMLBody = "Thank you!" & vbCrLf & olReply.HTMLBody
    olReply.send

    olItem.Display
    Set objInsp = ActiveInspector
    objInsp.CommandBars.ExecuteMso ("Delete")

End If

MsgBox "This slows down the processing."

On Error Resume Next
' Error when no items left
Set olItem = ActiveExplorer.Selection.Item(1)
olItem.Display
On Error GoTo 0

ExitProc:
    Set olItem = Nothing
    Set olReply = Nothing
    Set objInsp = Nothing

End Sub

Answer 2

Remember to update Folder Name

olFolderName = "TEMP"

Sub Open_Next_olMessage()
    Dim olNamespace As Outlook.NameSpace
    Dim olFolder As MAPIFolder
    Dim olItem As MailItem
    Dim olReply As MailItem
    Dim olFolderName As String
    Dim olMsgBox As Integer
    Dim Cancel As Boolean

    olFolderName = "TEMP" '<-- Update Folder Name

'   // Set Inbox/SubFolder
    Set olNamespace = Session.Application.GetNamespace("MAPI")
'                                                             --> Folder Name
    Set olFolder = olNamespace.GetDefaultFolder(olFolderInbox).Folders(olFolderName)

'   // Loop through items in folder
    For Each olItem In olFolder.Items
        If (olItem.Class = olMail) Then
            olItem.Display True

            olMsgBox = MsgBox("Do you want to Reply to this Email", vbYesNoCancel)
            Set olReply = olItem.ReplyAll ' or Reply
            Set olItem = olItem

            If olMsgBox = vbCancel Then
                Cancel = True ' Exit
                Exit Sub
            ElseIf olMsgBox = vbYes Then
                   olReply.Display True
            ElseIf olMsgBox = vbNo Then
'                  do something
            End If

            olItem.Delete ' Delete Message
        End If
    Next

End Sub