clojure: initialize 2d vector

Question

in clojure I'm using the following function to initialize a 2d vector:

(defn vec2d [x y init]
  (vec (map 
         #(vec (map init (range x))) (range y))))

usage:

(def grid (vec2d 40 30 (fn [] "x")))

Since I'm new to the language, I ask myself if this is the most straight-forward way to do so. Has anyone an idea to optimize this?

This is pretty confusing. What are you trying to put in and what do you want to get out? — jmargolisvt, Dec 22 '15 at 22:58
sorry, there was something wrong in the code. now it's updated. — Anton Harald, Dec 22 '15 at 23:22
If you're doing a lot with 2D structures, you may want to consider core.matrix. — Mars, Dec 23 '15 at 18:16

score 3 · Answer 1 · answered Dec 23 '15 at 00:56

3

Under the assumption that you'll always want to initialize the entries of the vector to a constant, here's how I'd do this:

(defn vec2d
  "Return an x by y vector with all entries equal to val."
  [x y val]
  (vec (repeat y (vec (repeat x val)))))

answered Dec 23 '15 at 00:56

Aaron Harris

score 2 · Answer 2 · answered Dec 23 '15 at 02:44

if you want to be able to initialize according to the coordinate, you could do this

(defn vec2d [sx sy f]
  (mapv (fn[x](mapv (fn[y] (f x y)) (range sx))) (range sy)))

This allows you to have a constant value if you do

(vec2d 4 3 (constantly 2))
;; [[2 2 2 2] [2 2 2 2] [2 2 2 2]]

or initialize according to the coordinates, say:

(vec2d 4 3 (fn[x y] (+ x y))) 
(vec2d 4 3 +)                         ;; or more concisely
;;[[0 1 2 3] [1 2 3 4] [2 3 4 5]]

score 2 · Answer 3 · answered Dec 23 '15 at 11:35

Use mapv and you're set

(defn vec2d [x y init]
  (mapv #(mapv init (range x)) (range y)))

If you want the coordinates for initialization:

(defn vec2d [x y init]
  (mapv (fn [y] (mapv #(init % y) (range x))) (range y))

A nested for it's also very readable for boards generation if you just want all cells:

(defn vec2d [cols rows init]
  (for [x (range rows) y (range cols)]
    (init x y)))

Or if you don't mind seqs:

(defn vec2d [cols rows init]
  (for [x (range rows)]
    (for [y (range cols)]
      (init x y))))

score 0 · Answer 4 · edited May 19 '22 at 00:13

0

Using a threading macro:

(defn vec-2d [r c v] (->> (repeat c v) vec (repeat r) vec))

edited May 19 '22 at 00:13

Jeremy Caney

answered May 15 '22 at 22:15

mohan

As it’s currently written, your answer is unclear. Please [edit] to add additional details that will help others understand how this addresses the question asked. You can find more information on how to write good answers [in the help center](/help/how-to-answer). – Jeremy Caney May 19 '22 at 00:13

4 Answers4