9

How can I find the last row in a range of cells that hold a formula, where the result of the formula is an actual value and not empty?

Say in a simplified way that the range of cells ("E1:E10") hold a formula referring to cells A1 through A10 as followed =IF("A1"="","","A1"). But only the cells A1 through A6 have a value filled in, so the result of the formula for cells E7 through E10 will be empty.

Trying to do it with: 

lastRow = ActiveSheet.Range("E" & Rows.Count).End(xlUp).Row

results in lastRow having the value of 10. What I want is for the value of lastRow to be 6 in this example.

The actual code is way more complex than this so I can't just check for the last filled in Row of Column A, as the formulas refer to single cells on different sheets and are added dynamically.

Pascale
  • 135
  • 2
  • 7

4 Answers4

6

I think that more elegant way than was provided by @D_Bester is to use find() option without looping through the range of cells:

Sub test()
    Dim cl As Range, i&
    Set cl = Range("E1:E" & Cells(Rows.Count, "E").End(xlUp).Row)
    i = cl.Find("*", , xlValues, , xlByRows, xlPrevious).Row
    Debug.Print "Last row with data: " & i
End Sub

test

enter image description here

Also, more shorter version of the code which was provided above is:

Sub test2()
    Debug.Print [E:E].Find("*", , xlValues, , xlByRows, xlPrevious).Row
End Sub
Vasily
  • 5,707
  • 3
  • 19
  • 34
  • Works great and was more what I was looking for. I just have one question, what is the meaning of the ampersand `&` in the declaration of the variable `i`? (As it seems to work just the same without the ampersand) – Pascale Nov 29 '15 at 08:57
  • 2
    @Pascale it means `Dim i as Long`, if you will remove `&` then `i` will be declared `as Variant`. It just a shorthand method of coding, e.g. `%` is `Integer`, `&` is `Long`, `$` is `String`, `@` is `Currency`, `!` is `Single`, `#` is `Double`, if not specified then `Variant` – Vasily Nov 29 '15 at 10:37
  • 1
    @Vasily, thanks for giving me the whole list of shorthand declarations and -1 to Micrososft for not including them in their general [Declaring Variables](https://msdn.microsoft.com/en-us/library/office/gg264241.aspx) page – Pascale Nov 29 '15 at 11:29
  • 1
    This answer is elegant! Россия красиво – D_Bester Nov 29 '15 at 12:14
5

You want to find the last cell in a column that is not empty AND is not a blank string("").

Just follow the LastRow with a loop checking for a non-blank cell. 

lastrow = ActiveSheet.Range("E" & ActiveSheet.Rows.Count).End(xlUp).Row
Do
    If ActiveSheet.Cells(lastrow, 5).Value <> "" Then
        Exit Do
    End If
    lastrow = lastrow - 1
Loop While lastrow > 0

If lastrow > 0 Then
    Debug.Print "Last row with data: " & lastrow
Else
    Debug.Print "No data in the column"
End If

Notice that your Rows.count does not specify which sheet. That means it will use the active sheet. Of course ActiveSheet.Range() also is on the active sheet. But it is bad practice to mix Range or Rows with .Range or .Rows. It indicates a thoughtless usage that could bite you if you changed the ActiveSheet but didn't change the unspecified reference.

D_Bester
  • 5,723
  • 5
  • 35
  • 77
  • I had already thought about looping through them backwards like you suggest, but was hoping for a more elegant way to achieve it. – Pascale Nov 28 '15 at 12:58
  • Thank you for your answer and thank you for explaining how to improve the use of Rows.Count and ActiveSheet. – Pascale Nov 28 '15 at 13:09
  • 3
    I think there is, try using the "divide and conquer" approach. As `2^20` is equal to 1048576. That is the value of `Rows.Count`. That said your `Do...Loop` will never repeat more than 20 times to reach the `lastrow`. – Rosetta Nov 28 '15 at 15:26
  • 1
    @D_Bester there is another option to find the last non blank cell using `find()` option, withot looping through the range – Vasily Nov 28 '15 at 17:51
2

This should help you determine the last row containing a formula (in column A on sheet1 Sheet1):

lastRow  = Split(Split(Sheet1.Range("A:A").SpecialCells(xlCellTypeFormulas).Address, ",")(UBound(Split(Sheet1.Range("A:A").SpecialCells(xlCellTypeFormulas).Address, ","))), "$")(2)

SpecialCells is used to determine the range of all the cells containing a formula. This range is then parsed using Split. With Ubound the last of these cells is being retrieved. The result is being split again to extract the row number.

Ralph
  • 9,284
  • 4
  • 32
  • 42
  • I tried to apply your code but it returns the first row having a formula in it. (The range in my sheet is from row 3 to row 26 and your lastRow returns 3: when I print it out with MsgBox, when I expected it to be 21) Not sure what i need to adjust or even if this is a good approach. You say "This should help you determine the last row containing a formula" but i need the last row containing a formula where the result of that formula is not "" (empty string). Sorry if I misunderstood your answer but I have no experience with vba at all so I am totally relying on what i find on stackoverflow. – Pascale Nov 28 '15 at 12:57
  • 2
    @Ralph The Address property is limited to a 255-character string, and so may not include all of the areas containing formulas. – shg Nov 28 '15 at 18:17
0
Function returnLastRow()
    With ActiveSheet.UsedRange
    returnLastRow = .Find("*", , xlValues, , xlByRows, xlPrevious).Row
    End With
End Function
Ankur Aggarwal
  • 2,210
  • 2
  • 34
  • 39
OzDrooper
  • 11