Why are local variables variable is not respected?

Question

In this code snippet, fields-types in the end is modified by the to-camel-case function, vs. being passed as a local variable to the parent function:

fields-types: ["First Name" "string" "Last Name" "string" "Age" "int"]

to-camel-case: function [name] [
    name/1: lowercase name/1
    replace/all name space ""
]

fill-template-body: func [
    field-labels-types [block!] /local vars fields-names-types
] [
  vars: [member-name member-type]
  field-names-types: copy []
  foreach [field-label field-type] field-labels-types [
      append field-names-types to-camel-case field-label
      append field-names-types field-type
  ]
]

fill-template-body fields-types

Execution gives:

>> fill-template-body fields-types
== ["firstName" "string" "lastName" "string" "age" "int"]
>> fields-types
== ["firstName" "string" "lastName" "string" "age" "int"]
>>

Whereas I would want that fields-types to stay invariant:

fields-types: ["First Name" "string" "Last Name" "string" "Age" "int"]

Of course I can try to circumvent this by modifying to-camel-case to use a copy of name, but that is not something I think I should have to do.

Is there something like the var and val keywords in Scala?

rgchris · Accepted Answer · 2010-07-31T20:13:36.520

1

Variable is an ugly word in REBOL, everything - even words - are values. This isn't some semantic newspeak, it's helpful in understanding the way in which REBOL flows.

I think of values as being contained within one giant array in memory, where REBOL (the language) uses words and their contexts to reference and interact with the values. Most REBOL functions operate without duplicating these values:

head lowercase next uppercase str: "abcd"
remove back tail str

This is one of REBOL's most efficient features - you don't need copies for intermediary processes, to require such is wasteful. Think of that array growing where every time you use replace, uppercase or to-camel-case a value is duplicated. Whole processes can be built on the premise of modification rather than duplication - indeed a context can be built without necessarily having to return a value:

remove-spaces: use [space mark][
    space: charset " ^-"
    [any [mark: space (remove mark) | skip]]
]

parse/all str: "Should Be No Spaces" remove-spaces

The trick then becomes knowing where to copy values, and I think happens to intersect with REBOL's gift for concise expression:

parse/all link: copy title: "An Article on REBOL" remove-spaces
print ["(" link ")" title]

to-camel-case copy field-label

And of course, modification has its limitations. Sometimes it is cleaner building from scratch.

edited Jul 31 '10 at 20:13

answered Jul 31 '10 at 18:05

rgchris

3,698
19
19

Thanks will reread it several times. Still a mechanism would be usefull to give the choice, maybe something like val keyword http://reboltutorial.com/blog/scala-val-keyword/ ? will have to think about it. – Rebol Tutorial Jul 31 '10 at 20:16
Seems to me you want to 'protect a value, not a word(?) This doesn't happen in REBOL: foo: bar: "foobar" protect 'foo uppercase bar probe foo Protecting a word only prevents you from assigning it to another value. The value itself can still be manipulated via another reference, unless you use a copy. bar: copy foo: "foobar" protect 'foo uppercase bar probe foo – rgchris Jul 31 '10 at 20:33
I agree about comments and newline :) – Rebol Tutorial Aug 01 '10 at 18:54
What I want is a local classical behavior when I need it so I'd like some kind of flag or keyword to do so not everytime because I like the fact that rebol doesn't force locality but sometimes when I decide to. I want the choice to decide myself not that the language to impose to me. – Rebol Tutorial Aug 01 '10 at 18:57

score 1 · Answer 2 · answered Jul 31 '10 at 22:29

1

Your camel case function operates on the original value so if you want to preserve the original value, you need to copy it, and return the altered value. Since your function acts on a template it needs to copy the template right??

So, something like this should work:

fill-template-body: func[ labels [block!] /local field-labels-types vars fields-names-types][
  field-labels-types: copy labels
..

answered Jul 31 '10 at 22:29

Graham Chiu

4,856
1
23
41

yes that's what I've done but I just say that one should have an automatic mechanism like val keyword in scala maybe so as not to have to think about it each time. – Rebol Tutorial Aug 01 '10 at 18:54

Why are local variables variable is not respected?

2 Answers2