Out of Bounds error when Implementing an insertion sort

Question

It seems that VB.NET evaluates both sides of the Boolean condition While j >= 1 And Card(j - 1) > NextCard, which will of course lead to an out of bounds error.

Other languages I have programmed in would have evaluated the left condition first and exited the loop before the second condition would cause the program to crash.

Can anyone see an obvious solution or do I just need to make turn the algorithm into a convoluted mess?

Sub Main()
    Dim card() As Integer = {7, 4, 6, 8, 1, 5}
    Insertion_Sort(card)
    For Each item In card
        Console.WriteLine(item)
    Next
End Sub

Sub Insertion_Sort(ByRef Card() As Integer)
    Dim NextCard
    Dim j As Integer

    For i = 1 To Card.Length - 1
        NextCard = Card(i)
        j = i
        While j >= 1 And Card(j - 1) > NextCard
            Card(j) = Card(j - 1)
            j -= 1
        End While
        Card(j) = NextCard
    Next
End Sub

You can use AndAlso or OrElse to short circuit the statement. — Capellan, Nov 11 '15 at 12:28
Thanks for this... I have no idea how I have gone so long without knowing those commands in vb.net! — user2956578, Nov 11 '15 at 12:29
Why don't you open MSDN vb.net keywords page, and just look over what it has? — T.S., Nov 11 '15 at 16:05
On MSDN: https://msdn.microsoft.com/en-us/library/cb8x3kfz.aspx — vbnet3d, Nov 11 '15 at 17:33
Arguably because this is the first time I've needed them... I'll do that in the future though, thanks. — user2956578, Nov 23 '15 at 20:42

score 2 · Accepted Answer · answered Nov 11 '15 at 17:38

As Capellan suggested, short-circuit evaluation can be done using the AndAlso keyword in place of And:

While j >= 1 AndAlso Card(j - 1) > NextCard
     Card(j) = Card(j - 1)
     j -= 1
End While

This causes VB.Net to evaluate the first expression first, and then, only if the first expression is true, it evaluates the second.

I suggest you also review the MSDN page: https://msdn.microsoft.com/en-us/library/cb8x3kfz.aspx

Out of Bounds error when Implementing an insertion sort

1 Answers1