Copying directory+path to new location in windows batch (using robocopy)

Question

I'm attempting to standardize a portion of the copying in a script I was given.

Because of this it would be nice to re-write the following block:

REM Copy files
for %%x in (%var1%) do (
    copy %src%\%%x %dest%\%%x
)

where var1 contains strings in the format folder\folder\file.fileExtension, so an example would be:

var1=test\test1\test1.txt test\test1\test2.txt test\test3\randomfile.cmd

The destination doesn't exist yet (currently it's just created separately).

Unfortunately robocopy won't copy this way (It won't accept the format folder\file and folder\file as source and destination from what I've seen). This means I need to either break the variable at the last backslash into two variables or use a different copy tool (like copy or xcopy), but this is "discouraged".

Does anyone have a clever way of getting robocopy to accept this format without creating a new function to break the passed variable into two new variables? Or is there a different way to store an iterable list of folder\file paths that would remove this issue?

I've been able to retrieve the name portion from the passed parameter given %%~n but am unable to retrieve the path portion of the passed parameter as it's not a full path. I attempted to use a for loop to just cut that portion off (similar to results here: Last token in batch variable)

That doesn't work as it's a \ deliminated string, and as far as I know you can't cycle through in FOREACH style in for /f.

Answer 1

This is the full solution I went with, which is very similar to what aschipfl posted (there are additional things I've modified from my actual script to make more sense - robocopy wrapper is a wrapper script that handles robocopy errors better for instance, and changing variable names):

....

REM Copy SWFs
set src=%SV1%\%V2%\%V3%
set dest=.\%DV1%\%V2%\%V3%
call :doPatchSWFFileCopy

set src=%SV1%\%V2%\%V3%
set dest=.\%DV1%\%DV2%\%V3%
call :doPatchSWFFileCopy

....

:doPatchSWFFileCopy
SETLOCAL EnableDelayedExpansion
for %%I in (%_filelist_%) do (
    REM Append file path to source and dest, as well as a pipe to prevent same name copies
    set "src=%src%\%%~I|"
    set "dest=%dest%\%%~I|"
    REM Truncate only LAST item (file name + extension) and the pipe character from the paths:
    set "src=!src:%%~nxI|=!"
    set "dest=!dest:%%~nxI|=!"
    REM truncate trailing slash
    call %robocopywrapper% "!src:~,-1!" "!dest:~,-1!" "%%~nxI"
)
ENDLOCAL
goto :EOF

Answer 2

Considering your mentioned for block, you can replace copy with the robocopy command in the following way:

for %%v in (%listOfFiles%) do (robocopy %%~dv%%~pv %destinationPath% %%~nv%%~xv)

As already mentioned in the comments, %%~dv, %%~pv, %%~nv, %%~xv are statements which respectively expand the disk, the path (disk not included), the name and the extension of the %%v variable. Of course, this expansions are possible only with variables that point a path of a file. In the end, the syntax of the robocopy command requires at least a source path, a destination path and a list of files to copy. Then, if the destination path is previously defined, the script should work correctly.

Edit n.r 1
If in the %listOfFiles% file there are not full paths listed but only a portion of them, you can use the * character to try to fill it in the right way. A simple example of this functionality can be:

C:\Users\username>cd D*p
C:\Users\username\Desktop>_

Answer 3

The following code could work for you (see rem remarks for brief explanations):

rem define source and destination roots here (no trailing `\` allowed!):
set "src=D:\path\to\source\dir"
set "dst=D:\path\to\destin\dir"
rem define list of items here:
set var1="test\test1\test1.txt" "test\test1\test2.txt" "test\test3\randomfile.cmd"

setlocal EnableDelayedExpansion
for %%I in (%var1%) do (
    rem append variable item to source and destination roots,
    rem and append a `|` which is not allowed in file names:
    set "src=%src%\%%~I|"
    set "dst=%dst%\%%~I|"
    rem truncate only LAST item (name+ext.) and `|` from the paths:
    set "src=!src:%%~nxI|=!"
    set "dst=!dst:%%~nxI|=!"
    rem supply paths with trailing `\` removed and LAST item (name+ext.) to `robocopy`:
    robocopy "!src:~,-1!" "!dst:~,-1!" "%%~nxI"
)
endlocal

As you might notice, there is a pipe symbol | appended temporarily, which is a forbidden character for file paths. This has been done that the approach does not fail even in case one or more directories in all the affected trees have got the same name as any of the copied files (test1.txt, test2.txt or randomfile.cmd in the example).