How to convert HEX to ASCII in ActionScript

Question

For example, is there any methods existing in ActionScript that can convert 0x4e544c4d into ASCII string "NTLM"?

Answer 1

You can try like this:

function HexToASCII(s:String):String {
    var hexChar:String;
    var finalString:String = "";
    for (var i = 0; i < s.length/2; i++) {
        hexChar = s.charAt(i*2).toString()+s.charAt((i*2)+1).toString();
        hexChar = "0x"+hexChar;
        finalString = finalString+String.fromCharCode(parseInt(hexChar));
    }
    return finalString;
}

Answer 2

I found "a native way" to achive what you asked for: a combination of the methods writeInt/writeByte and toString of flash.utils.ByteArray:

import flash.utils.ByteArray;

var hex:String = '0x4e544c4d';
var hexNum:int = parseInt(hex);
var bytes:ByteArray = new ByteArray();
bytes.writeInt(hexNum);
trace(bytes.toString()); //prints NTLM

Of course you need to take care of the maximum value parseInt returns (Number can only contain 53 bits.), and how that matches when writing to the ByteArray. I made a small function to handle longer hex strings:

import flash.utils.ByteArray;

var hex:String  = '0x4e544c4d204e544c4d204e544c4d';
trace(hexToAscii(hex));//NTLM NTLM NTLM

function hexToAscii(hex:String):String {
    if (hex.indexOf('0x') === 0){
        hex = hex.substr(2);
    }
    var bytes:ByteArray = new ByteArray();
    while (hex.length > 1){
        bytes.writeByte( parseInt(hex.substr(0,2), 16) );
        hex = hex.substr(2);
    }
    return bytes.toString();
}

You can play with it: http://wonderfl.net/c/IUn2