Return different text based on time and day of the week

Question

I am looking for a way, basically, to code an alarm clock for my computer. I want it to show the time, day of the week, month and day, and then based off that, I want it to show a message and play a sound once. I have four dynamic text boxes on the stage: time, display, day, date.

import flash.net.URLRequest;
import flash.media.Sound;

time.text = getTime();
function getTime(){
    var time = new Date();
    var hour = time.getHours();
    var minute = time.getMinutes();
    var temp = "" + ((hour > 12) ? hour - 12 : hour);
    temp += ((minute < 10) ? ":0" : ":") + minute;
    temp += (hour >= 12) ? " PM" : " AM";
    return temp;
}

day.text = getToday();
function getToday(){
    var weekday_array:Array = new Array("Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday");
    var today = new Date();
        var weekday:String = weekday_array[today.getDay()];
        var temp = weekday + ","; 
    return temp;
}

date.text = getDayz();
function getDayz() {
    var month_array:Array = new Array("January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December");
    var calendar = new Date();
        var number = calendar.getDate();
        var month:String = month_array[calendar.getMonth()];
        var temp = month + " ";
        temp += number;  
   return temp;
}

    display.text = getDisplay();
    function getDisplay(){
        time.text = getTime();
        day.text = getToday();
        date.text = getDayz();

}

Without the display.text block, everything works perfectly. When I try and fiddle with that last bit, either by doing a for or if function, it throws the whole thing off.

How do I make the display text box read what's in the other boxes, and then return a phrase based on those values? I took a basic class in actionscript like four years ago, so layman's terms would be highly appreciated.

Answer 1

To start, about your getDisplay() function, you should know that if you want that the text of a text field get the returned value of a function you have to use "return" inside that function to return a String object (as you did with your 3 others function).

Also, you are not forced to use text fields to put your informations before set it to a final text field.

So in your case, if you don't need to use the time, day and date text fields, you can set display.text like this :

display.text = getTime() + getToday() + getDayz();

But you can more simplify things using a flash.globalization.DateTimeFormatter object which will do the job for you and you have just to show what you need in your text field(s), like this :

// I'm not in USA, that's why I used "en-US" to get the english format (for the example)
// for you, you can simply use LocaleID.DEFAULT, you will get your local format
var df:DateTimeFormatter = new DateTimeFormatter('en-US');  

    // get the time 
    // hh : hour of the day in a 12-hour format in two digits [01 - 12]
    // mm : minute of the hour in two digits [00 - 59]
    // a  : AM/PM indicator
    df.setDateTimePattern('hh:mm a');
    trace(df.format(new Date()));       // gives : 11:02 AM

    // get the day
    // EEEE : full name of the day in week
    df.setDateTimePattern('EEEE');
    trace(df.format(new Date()));       // gives : Friday

    // get the day and month
    // MMMM : full name of the month
    // dd   : day of the month in two digits [01 - 31]
    df.setDateTimePattern('MMMM dd');
    trace(df.format(new Date()));       // gives : September 18

Of course you can put those values into variables and then use them with your text field(s).

For more details about the pattern string used by the DateTimeFormatter object to format dates and times, take a look on the setDateTimePattern() function.

Hope that can help.