Looping over distinct values

Question

Given a variable which returns a list of distinct States using the distinct-values() function, is there a way to tokenize the variable in a for-each loop?

<States>
<State>AL</State>
<State>AL</State>
<State>NM</State>
</States>

The following variable returns AL and NM, but I can't iterate over it using for-each. Is there a way around this?

<xsl:variable name="FormStates" select="distinct-values(States/State)"/>
  <xsl:for-each select="$FormStates">

XSLT 2.0 ok.

As always, it is not clear at all what problem you have. Learn to provide: 1. The source XML document. 2. The wanted result. 3. The required properties of the transformation. — Dimitre Novatchev, Jul 14 '10 at 12:51
I have voted to CLOSE this question. It is not really a question -- no question is being asked. The problem is not defined and is not clear. — Dimitre Novatchev, Jul 14 '10 at 12:52

score 5 · Accepted Answer · answered Jul 15 '10 at 11:52

The distinct-values() function returns a sequence of values which you should be able to iterate over. The result is so to speak "tokenized".

fn:distinct-values('AL', 'AL', 'NL') returns the sequence ('AL', 'NL').

If you output the variable with xsl:value-of it will return the string "AL NL" only because the default sequence separator for xsl:value-of is a single space character. This is something you could change with the @separator attribute:

Input

<?xml version="1.0" encoding="UTF-8"?>
<States>
  <State>AL</State>
  <State>AL</State>
  <State>NM</State>
</States>

XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:template match="/">
    <xsl:variable name="FormStates" select="distinct-values(States/State)"/>
    <xsl:comment>xsl:value-of</xsl:comment>
    <xsl:value-of select="$FormStates" separator=":"/>
    <xsl:comment>xsl:for-each</xsl:comment>
    <xsl:for-each select="$FormStates">
      <xsl:value-of select="."/>
      <xsl:text>:</xsl:text>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

Output

<?xml version="1.0" encoding="UTF-8"?>
<!--xsl:value-of-->
AL:NM
<!--xsl:for-each-->
AL:NM:

Thanks. I wasn't aware of the separator attribute. I ended up building a delimited string and using tokenize(), but I will go back and clean it up. — johkar, Jul 15 '10 at 17:14

score 2 · Answer 2 · answered Sep 19 '13 at 04:33

Here's an XSLT 1.0 solution that I've used in the past.

  <xsl:template match="/">           
    <ul> 
      <xsl:for-each select="//State[not(.=preceding::*)]">
        <li>
          <xsl:value-of select="."/>
        </li>   
      </xsl:for-each>            
    </ul>
  </xsl:template>

Returns:

<ul xmlns="http://www.w3.org/1999/xhtml">
  <li>AL</li>
  <li>NM</li>
</ul>

score 0 · Answer 3 · answered Jul 15 '10 at 11:21

In theory it should work; are you sure the XPath given to the distinct-values function is correct? The code you've given requires that the States element is a sibling of the forms element.

You could insert <xsl:value-of select="count($FormStates)"> immediately after the variable declaration to confirm if it is being set properly.

Looping over distinct values

3 Answers3

Linked