Delphi XE8: MemoryStream is filled with junk

Question

IdFTP_Main.Get('test.ini',MemoryStream);
MemoryStream.Read(Buffer,MemoryStream.Size);
SetString(TempStatus, PChar(MemoryStream.Memory), MemoryStream.Size div SizeOf(WideChar));

test.ini contains a short, plain text string. The memory size in MemoryStream.Size says 8, which is correct. The content of TempString is over a hundred control characters. All help appreciated.

Edit: This code produces the correct file, but requires me to write a copy, which isn't secure:

IdFTP_Main.Get('test.ini',MemoryStream);
MemoryStream.Position := 0;
MemoryStream.SaveToFile('./test.ini');

Answer 1

You are treating the stream as though it is UTF-16LE encoded. I suspect that's not the case. You need to determine the encoding. Then use a string stream like this:

var
  Stream: TStringStream;
  Str: string
....
Stream := TStringStream.Create('', TEncoding.UTF8);
try
  IdFTP_Main.Get('test.ini', Stream);
  Str := Stream.DataString;
finally
  Stream.Free;
end;

Or a bytes stream like this:

var
  Stream: TBytesStream;
  Str: string
....
Stream := TBytesStream.Create;
try
  IdFTP_Main.Get('test.ini', Stream);
  Str := TEncoding.UTF8.GetString(Stream.Bytes, 0, Stream.Size);
finally
  Stream.Free;
end;

I've guessed at an encoding. You'll need to substitute the correct encoding.

The call to the stream's Read method makes no sense in this situation. I've just ignored that.

We can't see how you configured the TIdFTP object. Is TransferType set correctly? In order for you to debug this further, use the bytes stream code above and dump the bytes that are downloaded. Check that they match your expectation.