TargetPath is blank - on remote drives

Question

I can't seem to get the WShell to return a value for objShortcut.TargetPath, although it passes the full name fine.

I've been reading that the WShell can have issues with remote disks, and I had been using an external drive.

After testing it on shortcuts on my C: drive with files located on my C: drive, I am finding it still does not work. Instead of echoing the traget path, it echos a blank value.

Edited. Thanks for the tip.

getshorty.vbs

Dim objWSHShell
set objWSHShell = CreateObject("WScript.Shell")  
Set wshShell    = WScript.CreateObject("WScript.Shell")  
strTargetPath=objWSHShell.ExpandEnvironmentStrings(WScript.Arguments.Item(0))  
Set objShortcut = wshShell.CreateShortcut(strTargetPath)  
WScript.Echo objShortcut.TargetPath  
Set objShortcut = Nothing  
Set wshShell    = Nothing

Please [edit] your question (don't post in comment) and add sample output from `WScript.Echo WScript.Arguments.Item(0)` and `WScript.Echo strTargetPath`. — JosefZ, Sep 06 '15 at 11:02

JosefZ · Answer 1 · 2015-09-06T13:01:28.950

Of course, TargetPath property results to "" (a string of zero length) if the .lnk or .url file does not exist.

The CreateShortcut method returns either a WshShortcut object or a WshURLShortcut object. Simply calling the CreateShortcut method opens an existing shortcut but does not result in the creation of a shortcut.

option explicit
On Error GoTo 0

Dim wshShell, strTargetPath, objShortcut 
Set wshShell  = WScript.CreateObject("WScript.Shell")
strTargetPath = wshShell.ExpandEnvironmentStrings(WScript.Arguments.Item(0))

Set objShortcut = wshShell.CreateShortcut(strTargetPath)

WScript.Echo TypeName(objShortcut) & vbTab & VarType(objShortcut) _
           & vbNewLine & "FullName"    & vbTab & objShortcut.FullName _
           & vbNewLine & "TargetPath"  & vbTab & objShortcut.TargetPath
If TypeName(objShortcut) = "IWshShortcut" Then            
  WScript.Echo      "Arguments"   & vbTab & objShortcut.Arguments _
      & vbNewLine & "Description" & vbTab & objShortcut.Description _
      & vbNewLine & "WorkingDir"  & vbTab & objShortcut.WorkingDirectory
End If

Output

==>dir /B d:\xxxx\*Shortcut.*
32421790 Shortcut.url
pisma - Shortcut.lnk

==>cscript D:\VB_scripts\SO\32421790.vbs "d:\xxxx\32421790 Shortcut.url"
IWshURLShortcut 8
FullName        d:\xxxx\32421790 Shortcut.url
TargetPath      http://stackoverflow.com/q/32421790/3439404

==>cscript D:\VB_scripts\SO\32421790.vbs "d:\xxxx\nonexistent Shortcut.url"
IWshURLShortcut 8
FullName        d:\xxxx\nonexistent Shortcut.url
TargetPath

==>cscript D:\VB_scripts\SO\32421790.vbs "d:\xxxx\pisma - Shortcut.lnk"
IWshShortcut    8
FullName        d:\xxxx\pisma - Shortcut.lnk
TargetPath      D:\bat\SU\Files\ruzna pisma.png
Arguments
Description     font samples
WorkingDir      D:\bat\SU\Files

==>cscript D:\VB_scripts\SO\32421790.vbs "d:\xxxx\nonexistent Shortcut.lnk"
IWshShortcut    8
FullName        d:\xxxx\nonexistent Shortcut.lnk
TargetPath
Arguments
Description
WorkingDir

==>

I get the same problem you have with the output in the second example. Target path is null. — 994a, Sep 06 '15 at 12:49

score 0 · Answer 2 · answered Sep 06 '15 at 12:34

This a function to create a shortcut :

Call Shortcut("C:\The Absolute Path of your application goes here","Name of your Shortcut")
'*********************************************************************************
Sub Shortcut(PathApplication,Name)
    Dim objShell,DesktopPath,objShortCut,MyTab
    Set objShell = CreateObject("WScript.Shell")
    MyTab = Split(PathApplication,"\")
    If Name = "" Then
        Name = MyTab(UBound(MyTab))
    End if
    DesktopPath = objShell.SpecialFolders("Desktop")
    Set objShortCut = objShell.CreateShortcut(DesktopPath & "\" & Name & ".lnk")
    objShortCut.TargetPath = Dblquote(PathApplication)
    ObjShortCut.IconLocation = "%SystemRoot%\system32\SHELL32.dll,-25"
    objShortCut.Save
End Sub
'*********************************************************************************
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'*********************************************************************************

TargetPath is blank - on remote drives

Edited. Thanks for the tip.

getshorty.vbs

2 Answers2