Can i create datatable using JSON string with an array value using vb?

Question

I've created a datatable using json string, though, some headers in my json string contains an array like this:

[{"Header1":"123","Header2":["asdasda"]}]

I successfully created a datatable using json but it doesn't show up the header that contains an array value like in the Header2. Here is my sample code in creating my datatable:

 strJson = Session("JsonStr").ToString
Dim tb As DataTable
tb = JsonConvert.DeserializeObject(Of DataTable)(strJson.ToString)

and everytime I try to fetch datatable to string, it appears. However, it only shows System.string[]. Using the json example I gave, the output is:

Header1=123 | Header2=System.string[]

Instead of fetching System.string[], can it fetch the value which is in array ("asdasda")? Here's my code in transfering datatable to string:

            Dim dr As DataRow
            Dim dc As DataColumn
            Dim sConcat As String = ""
            For Each dr In UpdatedTable.Rows
                For Each dc In UpdatedTable.Columns
                    sConcat = sConcat + dc.ColumnName + "= " + dr.Item(dc) + " | "
                Next
            Next dr

Answer 1

You are on the right track, but it would probably be easier to deserialize to a Type. Otherwise if the second column is an array then you need to access the data in it by index. You are seeing System.string[] (string array) in the results because you are simply referencing the array object not the data in the array:

dr.Item(dc)(0)

Since you cant know ahead of time how many items will be in the array for your loop, you need to convert column 1's data back into an array - the Row.Item are all Object so they can hold any sort of data.

' sample json, with 2 Hdr2 items
' the XML is just an easy way to have strings with quotes
' I added an item for testing purposes
Dim jstr = <str>
               [{"Header1":"123","Header2":["asdasda", "ziggy"]}]
            </str>.Value

Dim dt = JsonConvert.DeserializeObject(Of DataTable)(jstr)

Dim sRowData As String = ""
For n As Integer = 0 To dt.Rows.Count - 1
    sRowData = dt.Columns(0).ColumnName & " = " & dt.Rows(n).Item(0).ToString & " | "
    sRowData &= dt.Columns(1).ColumnName & " = "

    ' convert col 1 to an array, Join the elements
    Dim names As String() = CType(dt.Rows(n).Item(1), String())
    sRowData &= String.Join(", ", names)

    Console.WriteLine(sRowData)
Next n

Output:

Header1 = 123 | Header2 = asdasda, ziggy

I avoided having to iterate the array by using String.Join but iterating would be simple:

Dim names As String() = CType(dt.Rows(n).Item(1), String())

For j As Int32 = 0 To names.Length - 1
    sRowData &= names(j)
Next

Since dt.Rows(n).Item(1) is an object which we cannot iterate, you still need to convert it to a string array before looping on it.

Finally, you should turn on Option Strict. Since the cell/item data is stored as Object, with Option Strict on, the compiler would tell you this sort of code: + dr.Item(dc) + " | " isnt quite right.