SAS not recognizing date format

Question

I have the following character date format:

"3/1990"
"4/1990"
"5/1990"
...

I tried the following code:

data work.temps;
  set indata;
  newdate = input(strip(Date), MMYYSw.);
  rename newdate = date;
run;

I keep on getting the following error meassage: Informat MMYYSW was not found or could not be loaded.

You might try `MMYYS.` in place of `MMYYSw.`. See if that makes any difference — ander2ed, Aug 13 '15 at 15:05

score 6 · Accepted Answer · answered Aug 13 '15 at 15:28

6

You may have to use a different informat to read in the character dates so that SAS can interpret them as numeric (since dates in SAS are actually numeric values), and then format them as MMYYS..

This was tested and works for me:

DATA temps;
FORMAT newdate MMYYS.;
SET indata;
newdate = INPUT(COMPRESS('01/'||date),DDMMYY10.);
RUN;

answered Aug 13 '15 at 15:28

ander2ed

1,318
1
11
19

Thank you. I will say that your answer does make a nice distinction between FORMAT and INFORMAT. – ander2ed Aug 13 '15 at 15:32

score 3 · Answer 2 · answered Aug 13 '15 at 15:54

3

Try this with anydtdte:

data have;
    input date $10.;
    _date=input(compress(date,'""'),anydtdte.);
    format _date MMYYs7.;
    cards;
    "3/1990"
    "4/1990"
    "5/1990"
    ;
    run;

answered Aug 13 '15 at 15:54

Shenglin Chen

4,504
11
11

score 1 · Answer 3 · answered Aug 13 '15 at 15:29

What you refer is a FORMAT, not INformat. You'll use format with PUT function, for INPUT, you need informat.

Anyway I didn't find a suitable informat to be used directly, so you'll need to do more stuff:

data work.temps;
infile cards truncover;
input Date $10.;
newdate=MDY( scan(Date,1, '/'), 1, scan(Date,2, '/') );
cards;
3/1990
4/1990
5/1990
;
run;

SCAN takes Nth word from a string, MDY creates DATE from Month, Day and Year. The code above gives the first day of the month.

SAS not recognizing date format

3 Answers3

Linked