How to check if the string is a valid GUID?

Question

I need to validate the user input and check if the entered string is a valid GUID. How can I do that? Is there some sort of IsValidGuid validation function?

Answer 1

You can call the WinAPI function CLSIDFromString and check (at its failure) if the returned value was not CO_E_CLASSSTRING (which stands for an invalid input string). Calling the built-in StringToGUID function is not reliable as it raises exception from which you're not able to get the reason of the failure.

The following function returns True if the input string is a valid GUID, False otherwise. In case of other (unexpected) failure it raises an exception:

const
  S_OK = $00000000;
  CO_E_CLASSSTRING = $800401F3;

type
  LPCLSID = TGUID;
  LPCOLESTR = WideString;

function CLSIDFromString(lpsz: LPCOLESTR; pclsid: LPCLSID): HRESULT;
  external 'CLSIDFromString@ole32.dll stdcall';

function IsValidGuid(const Value: string): Boolean;
var
  GUID: LPCLSID;
  RetVal: HRESULT;
begin
  RetVal := CLSIDFromString(LPCOLESTR(Value), GUID);
  Result := RetVal = S_OK;
  if not Result and (RetVal <> CO_E_CLASSSTRING) then
    OleCheck(RetVal);
end;

Answer 2

How about this?

Uses System.SysUtils;

function IsValidGuid(GUID: String): Boolean;
begin
  try
    StringToGUID(GUID);
    Result := True;
  except
    Result := False;
  end;
end;

If the StringToGUID function is not successful in converting a string to a TGUID, it will raise an error. This is how I used it in my project and it works fine.

Another alternative:

function IsValidGuid(const GUID: string): Boolean;
var
  G: string;
  L: Integer;
begin
  Result := False;
  L := Length(GUID);
  if not (L in [36, 38])  then
    Exit;
  G := UpperCase(GUID);
  if (L = 38) and (G[1] = '{') and (G[L] = '}') then
    G := Copy(G, 2, L - 2);
  Result := (Length(G) = 36) and (G[09] + G[14] + G[19] + G[24] = '----');
  if Result then
  begin
    G := StringReplace(G, '-', '', [rfReplaceAll]);
    for L := 1 to 32 do
      Result := Result and (G[L] in ['0'..'9', 'A'..'F']);
  end;
end;