Use SAS Macro Variable within Proc SQL Teradata passthrough

Question

I have a SQL statement that I wish to automate using SAS EG (9.4). The following statement has been tested in Teradata SQL Assistant and works.

select * from TD.DATA where date='2015-06-01'

Now I wish to push this through a proc SQL pass through, and feed the date to the SQL program, like so....

proc sql;
connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
create table MYDATA as 
select * from connection to tera
(
select * from TD.DATA where date='2015-06-01'
);
disconnect from tera;
quit;

The above code has been tested and produces the exact same output as the previous SQL statement. However, what I really want is to do something like this:

%let input_date='2015-06-01';
proc sql;
connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
create table MYDATA as 
select * from connection to tera
(
select * from TD.DATA where date=&input_date.
);
disconnect from tera;
quit;

I have tried various combinations of quotations and different date formats....what am I missing here? Thanks.

Strange - that code you provide looks fine to me (with the single quotes being assigned inside the macro variable). I tested it against a mySQL database and it worked fine. Can you try it one more time just to humor me because I find it difficult to believe that it isn't working. Maybe do it in a new SAS session. — Robert Penridge, Apr 04 '16 at 16:04

score 7 · Accepted Answer · answered Jul 30 '15 at 08:20

7

You can use the %BQUOTE() macro function to resolve macro variables within single quotes.

%let input_date = 2015-06-01;
proc sql;
  connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
  create table MYDATA as 
  select * from connection to tera
  (
   select * from TD.DATA where date = %BQUOTE('&INPUT_DATE')
  );
  disconnect from tera;
quit;

answered Jul 30 '15 at 08:20

Chris J

7,549
2
25
25

Thanks, Chris! This solution is perfect, and I learned a new macro function. – pyll Jul 30 '15 at 11:56
I am getting "Teradata prepare: A character string failed conversion to a numeric value". Any ideas? – cs0815 Jan 14 '17 at 13:35
@csetzkorn Does the string represent a valid date? – Chris J Jan 16 '17 at 09:53

Stig Eide · Answer 2 · 2015-07-30T12:51:54.377

1

Try this:

%let input_date=2015-06-01;
proc sql;
connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
create table MYDATA as 
select * from connection to tera
(
select * from TD.DATA where date=%str(%'&input_date%')
);
disconnect from tera;
quit;

edited Jul 30 '15 at 12:51

answered Jul 30 '15 at 06:30

Stig Eide

1,052
7
14

Thanks, Stig. This works perfectly, though I prefer Chris J's solution. It looks a little cleaner. – pyll Jul 30 '15 at 11:56
Hi, yeah the BQUOTE looked better, Im going to use that in the future too ;) – Stig Eide Jul 30 '15 at 12:52

score 0 · Answer 3 · edited Apr 04 '16 at 14:56

0

as with such format of date 201501 to make a working macrovariable

%let input_date = 201506;
%let input_date2=input(put(intnx('month',%sysfunc(inputn(&input_date,yymmn6.)),0,'b'),10.),yymmddd10.)
proc sql;
  connect to teradata as tera(user=&tera_user password="&tera_pwd" tdpid=terap);
  create table MYDATA as 
  select * from connection to tera
  (
   select * from TD.DATA where date = %BQUOTE('&INPUT_DATE2')
  );
  disconnect from tera;
quit;

edited Apr 04 '16 at 14:56

mkluwe

3,823
2
28
45

answered Apr 04 '16 at 13:44

freza

1

Can you explain? What is the supposed effect of `%BQUOTE('&INPUT_DATE2')`? – mkluwe Apr 04 '16 at 14:15
just as input_date=2015-06-01 – freza Apr 05 '16 at 09:48

Use SAS Macro Variable within Proc SQL Teradata passthrough

3 Answers3

Linked