Search for a specific value in XML and Modify through VBS

Question

I was having a hard time to think of a way how to find a specific value and modify if found in an XML file. So, I began googling and found an article. However, I can't seem to understand the code that was used as a solution to their problem. I also tried modifying the code but unfortunately I could not make it worked.

<Configuration>
<Add SourcePath="\\sample" ApplicationEdition="32">
    <Product ID="SampleProductID">
      <Language ID="en-us" />
      <Language ID="en-us" />
    </Product>

I need to modify the content of this value <Add SourcePath= I've tried several times and no luck writing a vbscript to change its value. I would appreciate any help and thanks in advance.

Show the VBScript you are stuck with. – Tomalak Jul 28 '15 at 13:39 — Tomalak, Jul 28 '15 at 13:39

score 3 · Accepted Answer · edited May 23 '17 at 10:29

Publish complete/valid XML (cf here)
Show the code you have problems with
Link to your sources
Don't use antique tools (XMLDOM vs. msxml2.domdocument)
Avoid spurious () in Sub call
Use basic error handling (cf 1)
Use specific/strict XPath expressions (no // without reason)
Don't use Set x = Nothing just for fun

Demo:

Option Explicit

Dim oXDoc  : Set oXDoc = CreateObject( "Msxml2.DOMDocument" )
oXDoc.setProperty "SelectionLanguage", "XPath"
oXDoc.async = False
oXDoc.load "..\data\31677574.xml"

If 0 = oXDoc.ParseError Then
   WScript.Echo oXDoc.documentElement.xml
   Dim sXPath : sXPath    = "/Configuration/Add"
   Dim ndFnd  : Set ndFnd = oXDoc.selectSingleNode(sXPath)
   If Not ndFnd Is Nothing Then
      ndFnd.getAttributeNode("SourcePath").value = "SomeOtherValue"
      WScript.Echo "----------------", vbCrLf & oXDoc.documentElement.xml
   Else
      WScript.Echo sXPath, "- not found"
   End If
Else
   WScript.Echo oXDoc.ParseError.Reason
End If

output:

cscript 31677574-2.vbs
<Configuration>
        <Add SourcePath="\\sample" ApplicationEdition="32">
                <Product ID="SampleProductID">
                        <Language ID="en-us"/>
                        <Language ID="en-us"/>
                </Product>
        </Add>
</Configuration>
----------------
<Configuration>
        <Add SourcePath="SomeOtherValue" ApplicationEdition="32">
                <Product ID="SampleProductID">
                        <Language ID="en-us"/>
                        <Language ID="en-us"/>
                </Product>
        </Add>
</Configuration>

This was helpful, thanks for this script is now working. – xka Jul 30 '15 at 09:46 — xka, Jul 30 '15 at 09:46

score 0 · Answer 2 · answered Jul 28 '15 at 13:42

Try this code

Set xmlDoc = CreateObject("Microsoft.XMLDOM")
xmlDoc.Async = "False"
xmlDoc.Load("T.xml")
Set objAdd = xmlDoc.selectSingleNode("//Configuration/Add")
objAdd.Attributes.getNamedItem("SourcePath").Text = "Test"
xmlDoc.Save "T.xml"
Set objAdd = Nothing
Set xmlDoc = Nothing

I recommend you view these pages

Search for a specific value in XML and Modify through VBS

2 Answers2