Xtext custom validator warning - How to mark keyword?

Question

I have the simple Greeting example in xtext. So the DSL is defined like this:

grammar org.xtext.example.mydsl.Tests with org.eclipse.xtext.common.Terminals

generate tests "http://www.xtext.org/example/mydsl/Tests"

Model:
    greetings+= Greeting*;

Greeting:
    'Hello' name=ID '!';

Moreover, I have the following validator:

@Check
def checkGreetingStartsWithCapital(Greeting greeting) {
    if (!Character.isUpperCase(greeting.name.charAt(0))) {
        warning('Name should start with a capital', 
                TestsPackage.Literals.GREETING__NAME,
                -1,
                INVALID_NAME)
    }
}

If I write the validator like this and have an expression like "Hello world!" in my model, the "world" is marked, i.e. there is this yellow line under it. What do I have to do if I want to mark only the keyword so in this case only the "Hello"? I tried quite a few things and I can only manage to either mark the whole line "Hello world!" or just the "world".

Thank you!

score 5 · Accepted Answer · answered Jul 28 '15 at 06:00

5

have a look at the other methods for reporting a warning/error. there is one that takes an offset and length. you can use the node model to get them for the keyword

class MyDslValidator extends AbstractMyDslValidator {

    public static val INVALID_NAME = 'invalidName'
    @Inject extension MyDslGrammarAccess

    @Check
    def checkGreetingStartsWithCapital(Greeting greeting) {
        if (!Character.isUpperCase(greeting.name.charAt(0))) {
            val node = NodeModelUtils.findActualNodeFor(greeting)

            for (n : node.asTreeIterable) {
                val ge = n.grammarElement
                if (ge instanceof Keyword && ge == greetingAccess.helloKeyword_0) {
                    messageAcceptor.acceptWarning(
                        'Name should start with a capital',
                        greeting,
                        n.offset,
                        n.length,
                        INVALID_NAME
                    )
                }
            }

        }
    }
}

answered Jul 28 '15 at 06:00

Christian Dietrich

11,778
4
24
32

Could you update this answer? It seems like these days the validator API looks quite different. – Balz Guenat Oct 15 '19 at 11:12
@BalzGuenat what do you mean. the code is still perfectly fine – Christian Dietrich Oct 15 '19 at 16:41
@ChristianDietrich Hm, I was somehow under the impression that the `warning()` method had replaced the acceptor pattern. Is this not the case, then? Is one of the two ways preferred? How would I do the above with `warning()`? – Balz Guenat Oct 17 '19 at 11:28
1

you use warning. except you have EXACTLY this usecase – Christian Dietrich Oct 17 '19 at 12:24
@ChristianDietrich In contrast to other ways of marking things in XText, this seems pretty clumsy for a fairly common use case. Is this still the best way? – Safron Sep 01 '22 at 14:59
marking keywords and not assigning them in the grammar is still a uncommon usecase. – Christian Dietrich Sep 04 '22 at 19:17

score 1 · Answer 2 · answered Jul 30 '15 at 12:03

I found another very simple solution I haven't thought of that includes changing the DSL a bit, i.e. add the keyword as a attribute.

Greeting:
    keyword='Hello' name=ID '!';

Then the validator works as in the question:

@Check
def checkGreetingStartsWithCapital(Greeting greeting) {
    if (!Character.isUpperCase(greeting.name.charAt(0))) {
        warning('Name should start with a capital', 
                TestsPackage.Literals.GREETING__KEYWORD,
                -1,
                INVALID_NAME)
    }
}

Xtext custom validator warning - How to mark keyword?

2 Answers2