Code Path per Flavor in Android Gradle

Question

I have 2 buildTypes (debug, release) and 2 productFlavors (product1, product2). I want to define a buildConfigField for each buildType and productFlavors. The buildConfigField is the url the app to download data from the server, and it changes for each productFlavor and buildTypes.

Now, I have:

buildTypes {
    debug {
        debuggable true
    }
    release {
        debuggable false
    }
}
productFlavors {
    product1 {
        buildConfigField STRING, "URL_BASE",  '"https://api1.release.com"'

    }
    product2 {
        buildConfigField STRING, "URL_BASE", '"https://api2.release.com"'

    }
}

But I want something like this:

buildTypes {
    debug {
        debuggable true
    }
    release {
        debuggable false
    }
}
productFlavors {
    product1 {
        debug {
            buildConfigField STRING, "URL_BASE",  '"https://api1.debug.com"'
        }
        release {
            buildConfigField STRING, "URL_BASE",  '"https://api1.release.com"'
    }
    product2 {
        debug {
            buildConfigField STRING, "URL_BASE", '"https://api2.debug.com"'
            }
        release {
            buildConfigField STRING, "URL_BASE", '"https://api2.release.com"'
        }
    }
}

How I can achieve this?

Update:

Each URL_BASE has a different pattern so I can't group the URLs. A posible solution is to add the url base of the 2 flavor in the different build types and select the right one in the flavor.

buildTypes {
    debug {
        debuggable true
        buildConfigField STRING, API_VARIANT_PRODUCT1, '"api1.deb.com"'
        buildConfigField STRING, API_VARIANT_PRODUCT2, '"api2.debug.com"'

    }
    release {
        debuggable false
        buildConfigField STRING, API_VARIANT_PRODUCT1, '"api1.release.com"'
        buildConfigField STRING, API_VARIANT_PRODUCT2, '"api2.release.com"'
    }
}

productFlavors {
    product1 {
        buildConfigField STRING, URL_BASE, '"https://" + API_VARIANT_PRODUCT1 + "/v1"'
    }
    product2 {
        buildConfigField STRING, URL_BASE, '"https://" + API_VARIANT_PRODUCT2 + "/v1"'
    }
  }
}

UPDATE 2

If you need to add resources in gradle, like a 'KEY_MAP' the solution is in this page.

score 13 · Answer 1 · answered Jun 17 '15 at 01:40

Build Type is not part of Product Flavor and vice versa. Variant is calculated based on both build type and product flavor. Using this you can just create either an extension (option 1) or a property (option 2) with a consistent format using both product flavor and build type.

Option 1

ext.product1_release_base_url = 'http://baseurl.myproduct/public'
ext.product2_release_base_url = 'http://baseurl.yourproduct/secure'
ext.product1_debug_base_url = 'http://debugurl.myproduct/test'
ext.product2_debug_base_url = 'http://yourproduct/debug'

android {
    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
        debug {
            minifyEnabled false
        }
    }
    productFlavors {
        product1 {}
        product2 {}
    }
}

project.android.applicationVariants.all {variant ->
    def url = project.ext."${variant.flavorName}_${variant.buildType.name}_base_url"
    variant.buildConfigField('String', 'URL_BASE', "\"${url}\"")
}

Option 2

in gradle.properties

product1_release_base_url = 'http://baseurl.myproduct/public'
product2_release_base_url = 'http://baseurl.yourproduct/secure'
product1_debug_base_url = 'http://debugurl.myproduct/test'
product2_debug_base_url = 'http://yourproduct/debug'

in build.gradle

android {
    buildTypes {
        release {}
        debug {}
    }
    productFlavors {
        product1 {}
        product2 {}
    }
}

project.android.applicationVariants.all {variant ->
    def url = project."${variant.flavorName}_${variant.buildType.name}_base_url"
    variant.buildConfigField('String', 'URL_BASE', "\"${url}\"")
}

do we have to call "project.android.applicationVariants.all" explicitly. — Tushar Pandey, Sep 29 '16 at 07:54
There might be other way but I don't know. There is no declarative way of doing it that is what you are interested. — n4h0y, Nov 30 '16 at 21:28
Can you please let me know why "\"${url}\"" and not ${url} directly ? — TapanHP, Oct 05 '18 at 12:12
For option 2, you must supply the url without simple quotes: `product1_release_base_url = http://baseurl.myproduct/public` — venimania, Mar 28 '19 at 10:27
@n4h0y How to avoid non existing extra props? like for example you accidentally added new flavor product3, how to ignore this and continue the loop? — david, Aug 13 '19 at 04:35
@david you can do something like this ``` project.android.applicationVariants.all {variant -> if (variant.flavorName == "product1") { ... } } ``` — n4h0y, Aug 14 '19 at 05:52
@n4h0y yep i already manage to avoid non existing extra props by adding if `project.hasProperty` thanks. — david, Aug 16 '19 at 17:39

score 6 · Answer 2 · answered Jun 10 '15 at 11:39

@Beni, you can use something like this

buildTypes {
    debug {
        debuggable true
        buildConfigField("String", "API_VARIANT", '"debugvariant"')
    }
    release {
        debuggable false
        buildConfigField("String", "API_VARIANT", '"releasevariant"')
    }
}
productFlavors {
    product1 {
        buildConfigField("String", "URL_BASE", '"https://api1." + API_VARIANT + ".com"')
    }
    product2 {
        buildConfigField("String", "URL_BASE", '"https://api2." + API_VARIANT + ".com"')
    }
}

The problem with what you were proposing to do is that the last definition of the the buildConfigField STRING, "URL_BASE" values for each buildType will get used in all product flavors. So what you would end up with would be something like "https://api2.release.com" in both release versions.

Using the above you will end up with something like this in your BuildConfig files for each variant

// Fields from build type: debug
public static final String API_VARIANT = ["debugvariant"|"releasevariant"];
// Fields from product flavor: [product1|product2]
public static final String URL_BASE = "https://[api1|api2]." + API_VARIANT + ".com";

Hope this helps.

I changed my code like my updated question. I have different url schemes, so I couldn't apply your answer in the same way and I have to adapt it as you can see. — beni, Jun 10 '15 at 15:25

score 1 · Answer 3 · answered Jun 05 '15 at 13:16

I don't know how you can set different values for multiple BuildVariants (build types + flavor) in build.gradle with the buildConfigField method.

However you can use a different value for your url_base inside res/values/strings.xml.

Something like:

<string name="url_base">https://api1.debug.com</string>

Then you can create the same string resource in these folders:

 - app/src/product1Debug: Contains product1-debug-related code/resources
 - app/src/product1Release: Contains product1-release-related code/resources
 - app/src/product2Debug: Contains product2-debug-related code/resources
 - app/src/product2Release: Contains product2-release-related code/resources

Of course it isn't the same to have a value inside the BuildConfig and is less confortable than the configuration with build.gradle.

What about the java classes which are equals for each build types? Do I have to clone each java class to add in product1Debug, product1Release? Or do I have to create a folder called product1 and this code is in it?? For example a java class called SplashActivity.java that is the same for the build types debug and release in product1. Thanks — beni, Jun 10 '15 at 07:23
For java classes you have to put 1 class for each buildTypes. You can use in this case: `- app/src/debug:` `- app/src/product1Release` `- app/src/product2Release` — Gabriele Mariotti, Jun 10 '15 at 08:05

score 1 · Answer 4 · answered Jun 10 '15 at 17:19

applicationVariants.all { variant ->

   def apiVariant = variant.getFlavorName == "product1" ? "api1" : "api2"
   def server = variant.buildType.name == "debug" ? "debug" : "release"

   variant.buildConfigField STRING, URL_BASE, "http://" + apiVariant + "." + server + ".com"
}

Code Path per Flavor in Android Gradle

4 Answers4

Linked