"Tabify" all files in Visual Studio solution?

Question

There's a "tabify" command in

Edit > Advanced > Tabify Selected Lines

(and the Power Tools 2010 also provide this functionality on a per-file basis) but is there a way to do this for all code files in a solution?

ReSharper has a Clean Up command but the only half-suitable option I found there is to run formatting on all files which does more than I want (I don't want to run a complete formatting, just tabifying).

There is a nice solution based on regular expressions: https://stackoverflow.com/questions/11846090/is-there-a-solution-wide-way-to-untabify-the-whole-files — Al Kepp, Sep 04 '19 at 16:50
Possible duplicate of [Is there a solution-wide way to Untabify the whole files](https://stackoverflow.com/questions/11846090/is-there-a-solution-wide-way-to-untabify-the-whole-files) — Al Kepp, Sep 04 '19 at 16:50
This answer helped me a lot: https://stackoverflow.com/questions/33027879/regex-to-replace-spaces-with-tabs-at-the-start-of-the-line — Andrii Viazovskyi, Dec 06 '19 at 14:06

score 16 · Answer 1 · edited Jun 03 '15 at 17:45

16

If you have added the Microsoft Productivity Power tools extension (which if you haven't I would recommned) it adds an option to tabify files. This does not apply across all files in a solution, but it's prompted for when editing each file, on a per file basis. Not quite what you're after but a help.

Also you might try setting your IDE editor settings to use tabs, then do menu-edit-advanced-format document (CTRL+E,D). This will replace groups of tab length spaces with a tab, and that should be scriptable for all files in the solution via a macro.

edited Jun 03 '15 at 17:45

Étienne

4,773
2
33
58

answered Feb 20 '11 at 09:28

Pete Stensønes

5,595
2
39
62

Could you please elaborate more about how to use Microsoft Productivity Power Tools to tabify in VS2013? Thanks. – leoly Mar 08 '15 at 00:39
It provides a "prompt bar" at the top of an edit window when it detects mixed tabs and spaces offering to tabbify or spaceify the file. If memory serves this happened on load ad when you save, I don't think there is another way to force the action on a file. If you just want the tab/space fix this extension does just that:https://visualstudiogallery.msdn.microsoft.com/91a3f8ae-3152-438a-b5fc-fb37878dd007 – Pete Stensønes Mar 08 '15 at 20:38
1

Yeah. I have found that prompt bar. However, it seems that there is no way to tabify the whole solution's files. Anyway, thanks again. – leoly Mar 09 '15 at 00:19
I don'ty understand why Power Tools keeps asking me to tabify all the time, the same file... – Carlos ABS Apr 17 '15 at 16:11

score 5 · Answer 2 · edited May 23 '17 at 12:34

The request contains links to IDE macros that can do the job:
http://blogs.msdn.com/b/kevinpilchbisson/archive/2004/05/17/133371.aspx
http://web.archive.org/web/20090217094033/http://chriseargle.com/post/Format-Solution.aspx

Here is sample code for a Visual Studio macro that automatically formats all *.cs, *.h, *.cpp, and *.hpp files in an open solution, which includes converting spaces to tabs (depending on your Tab settings in Tools > Options > Text Editor > specific language or "All Languages" > Tabs):

Imports System
Imports EnvDTE
Imports EnvDTE80
Imports System.Diagnostics

Public Module ConvertTabsToSpaces

    Public Sub FormatSolution()
        Dim sol As Solution = DTE.Solution
        For i As Integer = 1 To sol.Projects.Count
            FormatProject(sol.Projects.Item(i))
        Next
    End Sub

    Private Sub FormatProject(ByVal proj As Project)
        If Not proj.ProjectItems Is Nothing Then
            For i As Integer = 1 To proj.ProjectItems.Count
                FormatProjectItem(proj.ProjectItems.Item(i))
            Next
        End If
    End Sub

    Private Sub FormatProjectItem(ByVal projectItem As ProjectItem)
        If projectItem.Kind = Constants.vsProjectItemKindPhysicalFile Then
            If projectItem.Name.LastIndexOf(".cs") = projectItem.Name.Length - 3 Then
                Dim window As Window = projectItem.Open(Constants.vsViewKindCode)
                window.Activate()
                projectItem.Document.DTE.ExecuteCommand("Edit.FormatDocument")
                window.Close(vsSaveChanges.vsSaveChangesYes)
            ElseIf ((projectItem.Name.LastIndexOf(".cpp") = projectItem.Name.Length - 4) OrElse (projectItem.Name.LastIndexOf(".hpp") = projectItem.Name.Length - 4) OrElse (projectItem.Name.LastIndexOf(".h") = projectItem.Name.Length - 2)) Then
                Dim window As Window = projectItem.Open(Constants.vsViewKindCode)
                window.Activate()
                projectItem.Document.DTE.ExecuteCommand("Edit.SelectAll")
                projectItem.Document.DTE.ExecuteCommand("Edit.FormatSelection")
                window.Close(vsSaveChanges.vsSaveChangesYes)
            End If
        End If

        'Be sure to format all of the ProjectItems.
        If Not projectItem.ProjectItems Is Nothing Then
            For i As Integer = 1 To projectItem.ProjectItems.Count
                FormatProjectItem(projectItem.ProjectItems.Item(i))
            Next
        End If

        'Format the SubProject if it exists.
        If Not projectItem.SubProject Is Nothing Then
            FormatProject(projectItem.SubProject)
        End If
    End Sub

End Module

Instructions (Visual Studio 2005, but similar for newer versions):

Launch Visual Studio
Tools > Macros > Macros IDE...
Right-click MyMacros > Add > Add New Item...
Select Module
Enter "ConvertSpacesToTabs" without quotes in the Name field
Click Add
Replace the contents of the new module with the code above
Click Save
Close the Macros IDE
Tools > Macros > Macro Explorer
Expand MyMacros > ConvertSpacesToTabs
Double-click on FormatSolution
Wait for the macro to finish

Edit
I updated the code to also support *.h, *.cpp, and *.hpp files using code from Siegmund Frenzel here: https://stackoverflow.com/a/14766393/90287

+1 for the Chris Eargle link. His macro does what the OP asked for. — Adam Caviness, May 31 '12 at 18:47
@William, I added a link to an archive of that page. Thank you. — Rami A., Sep 04 '13 at 23:56
@AndrewArnold, I've updated the answer to include the source code and instructions. — Rami A., Feb 18 '15 at 19:30
Didn't the user ask for converting spaces to tabs--not tabs to spaces ("tabify" not "untabify")? — thecoolmacdude, May 20 '16 at 17:05
@thecoolmacdude, you are correct. I've updated my answer accordingly. — Rami A., May 20 '16 at 20:15
Thanks for your answer! I have added details of how to get this working in the latest version of Visual Studio in another answer: https://stackoverflow.com/a/64751215/1563422 — Danny Beckett, Nov 09 '20 at 11:58

score 2 · Answer 3 · answered Jan 21 '11 at 13:35

2

as far as I know what "Tabify" does is this - it only replaces " " (4 spaces) with a tab, it does not change the formatting or anything else.

Although I would suggest using document formatting, the "tabification" could easily be done via a custom application which would mimic the same action on all the files that you want.

Hope this helps!

answered Jan 21 '11 at 13:35

brokenisfixed

653
1
9
21

1

You can run the following code on all the source code for the solution `Regex.Replace (sInput, "4_spaces", "\t");` it will tabify the source code in the same manner Power Tools do. Change the "4_spaces" to actual spaces in the code as StackOverflow strips multiple spaces.. – brokenisfixed Feb 08 '11 at 09:13
1

Will need to check it out but there might be edge cases like custom indenting which may need special handling and global search & replace may not work properly. But thanks for the tip. – Borek Bernard Feb 08 '11 at 12:12

score 1 · Answer 4 · answered Mar 19 '15 at 02:19

For vs2010, you can use the following find and replace (this example is for tabs to 4 spaces).

In the find box, enter: ^{ *} (^{ space *} tab)

In the replace box, enter \1 (\1 space space space space)

Check the condition box and set to regular expressions. Newer versions of vs use different regular expression syntax, but the same should be doable.

Update This worked by executing once for vb files, but required multiple passes for a resx file, so you may have to execute multiple times depending on the file type...

score 1 · Answer 5 · answered Nov 11 '20 at 02:03

There's a new way using the dotnet CLI:

Install dotnet format by running the following command:
dotnet tool install -g dotnet-format
Run it, replacing SolutionFile.sln with the path to your solution file, with the following command line:
dotnet format SolutionFile.sln

The indent_style of .editorconfig will be used to determine if the code will use tabs or spaces.

Danny Beckett · Answer 6 · 2020-11-09T14:20:16.517

Macros have been removed from Visual Studio 2013 onwards (and the new version of Macros uses JavaScript rather than VBScript), so to get Rami A.'s answer to work in Visual Studio 2019:

Download and install the Visual Commander extension
Extensions > VCmd > Edit macro
Name it
Paste the following code. I have had to make some changes to it to make the code work with Visual Commander. I have also changed the file extensions that it tabifies to .cs, .aspx and .ascx so change these if you need C++/other file extensions.

Imports System
Imports EnvDTE
Imports EnvDTE80
Imports System.Diagnostics
Imports Microsoft.VisualStudio.Shell
Imports VisualCommanderExt

Public Class ConvertTabsToSpaces
    Implements ICommand
    Sub Run(DTE As DTE2, package As Package) Implements ICommand.Run
        Dim sol As Solution = dte.Solution
        For i As Integer = 1 To sol.Projects.Count
            FormatProject(sol.Projects.Item(i))
        Next
    End Sub

    Private Sub FormatProject(ByVal proj As Project)
        If Not proj.ProjectItems Is Nothing Then
            For i As Integer = 1 To proj.ProjectItems.Count
                FormatProjectItem(proj.ProjectItems.Item(i))
            Next
        End If
    End Sub

    Private Sub FormatProjectItem(ByVal projectItem As ProjectItem)
        If projectItem.Kind = Constants.vsProjectItemKindPhysicalFile Then
            If (projectItem.Name.LastIndexOf(".cs") = projectItem.Name.Length - 3 OrElse (projectItem.Name.LastIndexOf(".aspx") = projectItem.Name.Length - 5 OrElse (projectItem.Name.LastIndexOf(".ascx") = projectItem.Name.Length - 5))) Then
                Dim window As Window = projectItem.Open(Constants.vsViewKindCode)
                window.Activate()

                Try
                    projectItem.Document.DTE.ExecuteCommand("Edit.RemoveAndSort")
                Catch
                    ' Do nothing
                End Try

                Try
                    projectItem.Document.DTE.ExecuteCommand("Edit.SelectAll")
                    projectItem.Document.DTE.ExecuteCommand("Edit.FormatSelection")
                Catch
                    ' Do nothing
                End Try

                window.Close(vsSaveChanges.vsSaveChangesYes)
            End If
        End If

        'Be sure to format all of the ProjectItems
        If Not projectItem.ProjectItems Is Nothing Then
            For i As Integer = 1 To projectItem.ProjectItems.Count
                FormatProjectItem(projectItem.ProjectItems.Item(i))
            Next
        End If

        'Format the SubProject if it exists
        If Not projectItem.SubProject Is Nothing Then
            FormatProject(projectItem.SubProject)
        End If
    End Sub

End Class

Save
Run
To save for future use: Extensions > VCmd > Save macro as command > Name it > Save

"Tabify" all files in Visual Studio solution?

6 Answers6