VBS Script - Need to change msgbox to echo

Question

I'm having a hard time converting this script to an echo instead of a msgbox output.

I need to output to go into a text file in C:\key.log instead of a message box with the key.

Anyone know how to go about this? Thanks!

Set WshShell = CreateObject("WScript.Shell")
MsgBox ConvertToKey(WshShell.RegRead("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId"))

Function ConvertToKey(Key)
Const KeyOffset = 52
i = 28
Chars = "BCDFGHJKMPQRTVWXY2346789"
Do
Cur = 0
x = 14
Do
Cur = Cur * 256
Cur = Key(x + KeyOffset) + Cur
Key(x + KeyOffset) = (Cur \ 24) And 255
Cur = Cur Mod 24
x = x -1
Loop While x >= 0
i = i -1
KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
If (((29 - i) Mod 6) = 0) And (i <> -1) Then
i = i -1
KeyOutput = "-" & KeyOutput
End If
Loop While i >= 0
ConvertToKey = KeyOutput
End Function

WorkSmarter · Answer 1 · 2015-04-16T11:58:55.233

2

The code below replaces the echo statement with a call to the FileSystemObject (FSO). This object can add, move, change, create, or delete folders (directories) and files on the Web server or desktop. The method we are particularly interested is CreateTextFile.

DIM fso, NewsFile, WshShell

Set WshShell = CreateObject("WScript.Shell")

Set fso = CreateObject("Scripting.FileSystemObject")
Set write2File = fso.CreateTextFile("C:\key.log", True)
write2File.WriteLine(ConvertToKey(WshShell.RegRead("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId")))
write2File.Close

Function ConvertToKey(Key)
Const KeyOffset = 52
i = 28
Chars = "BCDFGHJKMPQRTVWXY2346789"
Do
Cur = 0
x = 14
Do
Cur = Cur * 256
Cur = Key(x + KeyOffset) + Cur
Key(x + KeyOffset) = (Cur \ 24) And 255
Cur = Cur Mod 24
x = x -1
Loop While x >= 0
i = i -1
KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
If (((29 - i) Mod 6) = 0) And (i <> -1) Then
i = i -1
KeyOutput = "-" & KeyOutput
End If
Loop While i >= 0
ConvertToKey = KeyOutput
End Function

edited Apr 16 '15 at 11:58

answered Apr 16 '15 at 01:47

WorkSmarter

3,738
3
29
34

I get the following error when I run this .VBS script. - Char: 1 Error: Object required: "WshShell" Code: 800A01A8 Source: Microsoft VBScript runtime error – TechnicianOnline Apr 16 '15 at 07:39
1

He forgot to add this line : Set WshShell = CreateObject("WScript.Shell"), so if you add this line it shoud works ;) – Hackoo Apr 16 '15 at 11:52
1

@WorkSmarter and you deserve from me a +1 ;) – Hackoo Apr 16 '15 at 12:03
@WorkSmarter I used this script as a side option to work in the background, thank you very much! – TechnicianOnline Apr 20 '15 at 18:52

score 2 · Answer 2 · answered Apr 16 '15 at 09:36

2

Wscript.echo "message"

outputs a msgbox when run with wscript and echos to STDOUT when run with cscript in a command prompt.

cmd /c cscript //nologo c:\somepath\somefile.vbs > file.txt

answered Apr 16 '15 at 09:36

Trigger

81
2

2

So you only need to replace `msgbox` with `wscript.echo` and start it correctly. – Trigger Apr 16 '15 at 10:16

score 2 · Accepted Answer · answered Apr 16 '15 at 09:40

Try like this :

Option Explicit
Dim WshShell,RegKey,WindowsKey,LogFile,fso
Set WshShell = CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
RegKey = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId"
WindowsKey = ConvertToKey(WshShell.RegRead(RegKey))
LogFile = "c:\key.log"
if fso.FileExists(LogFile) Then 
    fso.DeleteFile LogFile
end If
MsgBox WindowsKey,VbInformation,WindowsKey 
Call WriteLog(WindowsKey,LogFile)
WshShell.Run LogFile
'***********************************************************************************************************
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim i,Chars,Cur,x,KeyOutput
    i = 28
    Chars = "BCDFGHJKMPQRTVWXY2346789"
    Do
        Cur = 0
        x = 14
        Do
            Cur = Cur * 256
            Cur = Key(x + KeyOffset) + Cur
            Key(x + KeyOffset) = (Cur \ 24) And 255
            Cur = Cur Mod 24
            x = x -1
        Loop While x >= 0
        i = i -1
        KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
        If (((29 - i) Mod 6) = 0) And (i <> -1) Then
            i = i -1
            KeyOutput = "-" & KeyOutput
        End If
    Loop While i >= 0
    ConvertToKey = KeyOutput
End Function
'*************************************************************************************************************
Sub WriteLog(strText,LogFile)
    Dim fs,ts 
    Const ForAppending = 8
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set ts = fs.OpenTextFile(LogFile,ForAppending,True)
    ts.WriteLine strText
    ts.Close
End Sub
'**************************************************************************************************************

This is awesome, I ended up using this script instead as it opens the text file after it extracts the Windows key for the user. Thank you! — TechnicianOnline, Apr 20 '15 at 18:51

VBS Script - Need to change msgbox to echo

3 Answers3

Linked

Related