How to save and load captions of several labels?

Question

I need to save and load captions of several labels. I tried use TMemo for this:

procedure TForm1.Button1Click(Sender: TObject);    
begin    
  if SaveDialog1.Execute then
  begin    
     Memo1.Lines.SaveToFile(saveDialog1.FileName+'.txt');    
  end;    
end;


procedure TForm1.Button2Click(Sender: TObject);
begin
  if OpenDialog1.Execute then
  begin
    Memo1.Lines.LoadFromFile(OpenDialog1.FileName);
  end;
end;

But I don’t know how to set and get specific data of Label1, Label2, etc on the TMemo.

Based on this idea later I will use other components as TEdit.

I just realized a contradiction in your explanation... Are you using `TLabel` controls or `TEdit` controls? — Jerry Dodge, Apr 08 '15 at 03:36
You need some structured storage like TIniFile or maybe a XML file. — whosrdaddy, Apr 08 '15 at 06:45
@JerryDodge I made a mistake, I am using TLabel controls, but based on this idea later I will use other components as TEdit .. — Goerman, Apr 10 '15 at 02:23
If you google the terms "delphi" and "TiniFile" you will get quite a few examples how to use it? — whosrdaddy, Apr 10 '15 at 06:57
@whosrdaddy Of course, 40,300 results, but for this question I think TiniFile is not the better option because there are a lot of components. — Goerman, Apr 10 '15 at 16:25

Jerry Dodge · Answer 1 · 2015-04-08T04:32:10.123

I believe the easiest way is to use a string list (TStringList) instead of a memo control. It allows you to save name/value pairs, so the names could be the names of your labels (or any other unique identifier), and their values are the captions to show in the labels.

procedure TForm1.LoadFile(AFilename: String);
var
  Lst: TStringList;
begin
  Lst:= TStringList.Create;
  try
    Lst.LoadFromFile(AFilename);
    Label1.Caption:= Lst.Values['Label1'];
    Label2.Caption:= Lst.Values['Label2'];
    ...
  finally
    Lst.Free;
  end;
end;

procedure TForm1.SaveFile(AFilename: String);
var
  Lst: TStringList;
begin
  Lst:= TStringList.Create;
  try
    Lst.Values['Label1']:= Label1.Caption;
    Lst.Values['Label2']:= Label2.Caption;
    ...
    Lst.SaveToFile(AFilename);
  finally
    Lst.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);    
begin    
  if SaveDialog1.Execute then begin    
    SaveFile(saveDialog1.FileName+'.txt');    
  end;    
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  if OpenDialog1.Execute then begin
    LoadFile(OpenDialog1.FileName);
  end;
end;

Based on this idea you can then pretty [`simply automate`](http://pastebin.com/5sLt5RYL) the process for all labels of the form. — TLama, Apr 08 '15 at 22:52
@TLama I was thinking about that but didn't have the time to mention it, let alone write it :-) — Jerry Dodge, Apr 08 '15 at 23:10

score 3 · Answer 2 · edited Apr 08 '15 at 05:26

It doesn't really make any sense to have a memo involved here. You're probably looking for a TStringList.

You need to write the label contents to the string list first:

procedure TForm1.Button1Click(Sender: TObject);
var
  SL: TStringList;
begin
  if SaveDialog1.Execute then
  begin
    SL := TStringList.Create;
    try
      SL.Add(Edit1.Text);
      SL.Add(Edit2.Text);
      // Rest of edits
      SL.SaveToFile(SaveDialog1.FileName);
    finally
      SL.Free;
    end;
  end;
end;

To read back:

procedure TForm1.Button2Click(Sender: TObject);
var
  SL: TStringList;
begin
  if OpenDialog1.Execute then
  begin
    SL := TStringList.Create;
    try
      SL.LoadFromFile(OpenDialog1.FileName);
      Edit1.Text := SL[0];
      Edit2.Text := SL[1];
      // Same for rest of edits
    finally
      SL.Free;
    end;
  end;
end;

If you're having to do this for a lot of edit controls, you're probably using the wrong user interface. Without knowing what you're trying to accomplish, it's hard to suggest something else though.

I personally would never encourage someone to copy values from labels to a memo control then to a file, and vice-versa. — Jerry Dodge, Apr 08 '15 at 03:01
@Jerry: I agree. Thought about the question (was watching something on TV) and was updating the answer when you commented. — Ken White, Apr 08 '15 at 03:02

score 0 · Accepted Answer · answered Apr 10 '15 at 02:40

I modified a little this code according to my requirements.

procedure TForm1.ButtonSaveClick(Sender: TObject);
var
  I: Integer;
  Strings: TStringList;
begin
  if SaveDialog1.Execute then
  begin
  Strings := TStringList.Create;
  try
    for I := 0 to ComponentCount - 1 do
      begin
      if Components[I] is TLabel then
        Strings.Values[Components[I].Name] := TLabel(Components[I]).Caption;
      if Components[I] is TEdit then
        Strings.Values[Components[I].Name] := TEdit(Components[I]).Text;
    end;
    Strings.SaveToFile(SaveDialog1.FileName);
  finally
    Strings.Free;
  end;
end;
end;

procedure TForm1.ButtonLoadClick(Sender: TObject);
var
  I: Integer;
  Control: TComponent;
  Strings: TStringList;
begin
  if OpenDialog1.Execute then
  begin
  Strings := TStringList.Create;
  try
    Strings.LoadFromFile(OpenDialog1.FileName);
    for I := 0 to Strings.Count - 1 do
    begin
      Control := FindComponent(Strings.Names[I]);
      if Control is TLabel then
        TLabel(Control).Caption := Strings.ValueFromIndex[I];
      if Control is TEdit then
        TEdit(Control).Text := Strings.ValueFromIndex[I];
    end;
  finally
    Strings.Free;
    end;
  end;
end;

How to save and load captions of several labels?

3 Answers3