Access violation RTTI dumping record containing record pointers

Question

uses RTTI;

type TMyRecord = packed record
  name : String[20];
  age  : Integer;
end;

type TMasterCtrl = packed record
  MyRecord: ^TMyRecord;  // Error can be avoided by changing to `MyRecord: Pointer;`
end;

procedure RTTIDump(Instance, ATypeInfo: Pointer; Memo: TStrings; NameWidth, FieldTypeWidth, ValueWidth: Integer; PaddingChar: Char);
var
  rType: TRTTIType;
  fields: TArray<TRttiField>;
  i: Integer;
begin
  rType := TRTTIContext.Create.GetType(ATypeInfo);
  Memo.Add(rType.ToString);
  fields := rType.GetFields;
  for i := 0 to High(fields) do
    Memo.Add(Format('%s: %s :: %s', [
      fields[i].Name.PadRight(NameWidth, PaddingChar),
      fields[i].FieldType.ToString.PadRight(FieldTypeWidth, PaddingChar),
      fields[i].GetValue(Instance).ToString.PadRight(FieldTypeWidth, PaddingChar) ]));
end;

procedure TForm3.Button2Click(Sender: TObject);
var
  myRecord    : TMyRecord;
  MasterCtrl: TMasterCtrl;
begin
myRecord.name := 'Fred Bloggs';
myRecord.age  := 23;

MasterCtrl.MyRecord := @myRecord;

RTTIDump(Addr(MasterCtrl), TypeInfo(TMasterCtrl), Memo1.Lines, 18, 18, 0, ' ');
end;

How to fix the access violation this code will create, still using pointer to record?

Please don't post random code without explaining what the actual problem is with it, which line of code is failing, error messages, etc. — Remy Lebeau, Apr 04 '15 at 08:46
Ok. Next time I will put comment at line 9 "Error can be avoided by changing to `MyRecord: Pointer;`" at end before the question "How to fix the access violation this code will create, still using pointer to record?" Happy? — wittrup, Apr 04 '15 at 09:05
I don't understand why you use short strings, or why you pack your records — David Heffernan, Apr 04 '15 at 09:53

LU RD · Answer 1 · 2015-04-04T09:16:24.510

4

You need to use a proper type declaration for your pointer.

type
  PMyRecord =^TMyRecord;
  TMyRecord = packed record
  name : String[20];
  age  : Integer;
end;

type TMasterCtrl = packed record
  MyRecord: PMyRecord;  
end;

edited Apr 04 '15 at 09:16

answered Apr 04 '15 at 08:47

LU RD

34,438
5
88
296

score 1 · Accepted Answer · edited Jun 20 '20 at 09:12

1

As LU RD said, you have to declare a proper pointer type for TMyRecord to get the correct RTTI generated for the TMasterCtrl.MyRecord field, otherwise the field[s].FieldType property crashes because there is no type information to retreive.

type
  PMyRecord = ^TMyRecord; // <-- here
  TMyRecord = packed record
    name : String[20];
    age  : Integer;
  end;

  TMasterCtrl = packed record
    MyRecord: PMyRecord;  
  end;

That being said, there are two other problems with your code:

fields[i].GetValue(@Instance)

Instance already contains the address of the TMasterCtrl instance. By using @, you are passing the wrong address to GetValue(). You need to drop the @:
```
 fields[i].GetValue(Instance)
```
do not call rType.Free. TRttiContext owns it and will free it for you.

edited Jun 20 '20 at 09:12

Community

1
1

answered Apr 04 '15 at 08:49

Remy Lebeau

555,201
31
458
770

3. Not checking to see if `fields[i].FieldType` is assigned before using it. – Nicholas Ring Apr 04 '15 at 10:07
@NicholasRing: One would not typically expect `FieldType` to fail, though. This is a fluke in RTTI generation, not retrieval. – Remy Lebeau Apr 05 '15 at 16:48
it is not a fluke but a bug in the RTTI generation, so testing to see if it is assigned or not is a precautionary measure. – Nicholas Ring Apr 07 '15 at 10:16

Access violation RTTI dumping record containing record pointers

2 Answers2