Tail command used in perl backticks

Question

I'm trying to run a tail command from within a perl script using the usual backticks.

The section in my perl script is as follows:

$nexusTime += nexusUploadTime(`tail $log -n 5`);

So I'm trying to get the last 5 lines of this file but I'm getting the following error when the perl script finishes:

sh: line 1: -n: command not found

Even though when I run the command on the command line it is indeed successful and I can see the 5 lines from that particular.

Not sure what is going on here. Why it works from command line but through perl it won't recognize the -n option.

Anybody have any suggestions?

Put the `-n 5` before the file name argument. Options should precede file names — in all classic Unix systems. The GNU toolset blurs that rule, but in case of doubt, options before file names will usually work. — Jonathan Leffler, Mar 25 '15 at 21:45
yeah I just realized that's the issue. I found an article that said put the option after the file name. — iLoveWagons, Mar 25 '15 at 21:49
@Jonathan Leffler, Putting `$log` at the end does fix the problem, but not for the reason you think it does. See my answer. — ikegami, Mar 25 '15 at 22:08

ikegami · Accepted Answer · 2015-03-25T22:10:37.210

6

$log has an extraneous trailing newline, so you are executing

tail file.log
 -n 5            # Tries to execute a program named "-n"

Fix:

chomp($log);

Note that you will run into problems if log $log contains shell meta characters (such as spaces). Fix:

use String::ShellQuote qw( shell_quote );

my $tail_cmd = shell_quote('tail', '-n', '5', '--', $log);
$nexusTime += nexusUploadTime(`$tail_cmd`);

edited Mar 25 '15 at 22:10

answered Mar 25 '15 at 22:03

ikegami

367,544
15
269
518

score 3 · Answer 2 · edited May 23 '17 at 10:26

ikegami pointed out your error, but I would recommend avoiding external commands whenever possible. They aren't portable and debugging them can be a pain, among other things. You can simulate tail with pure Perl code like this:

use strict;
use warnings;

use File::ReadBackwards;

sub tail {
    my ($file, $num_lines) = @_;

    my $bw = File::ReadBackwards->new($file) or die "Can't read '$file': $!";

    my ($lines, $count);
    while (defined(my $line = $bw->readline) && $num_lines > $count++) {
        $lines .= $line;
    }

    $bw->close;

    return $lines;
}

print tail('/usr/share/dict/words', 5);

Output

ZZZ
zZt
Zz
ZZ
zyzzyvas

Note that if you pass a file name containing a newline, this will fail with

Can't read 'foo
': No such file or directory at tail.pl line 10.

instead of the more cryptic

sh: line 1: -n: command not found

that you got from running the tail utility in backticks.

If he had properly escaped `$log`, he would have gotten `tail: cannot open \`foo\n' for reading: No such file or directory`. (That's actually `\ ` followed by `n`, not a newline.) Just because you shell out doesn't mean you can't get good error messages. — ikegami, Mar 25 '15 at 22:19

score 0 · Answer 3 · answered Mar 25 '15 at 21:49

0

The answer to this question is to place the option -n 5 before the target file

answered Mar 25 '15 at 21:49

iLoveWagons

1,091
4
17
30

Tail command used in perl backticks

3 Answers3

Output