get new data from old one SAS

Question

I'm new in SAS and I have this example :

proc iml;  
x={1 2 3 4 5 6 7 8 9};
y={2,3,5,4,8,6,4,2,2};
z={1,1,1,1,2,2,2,2,2};
data=t(x)||y||z;
print data;    
run;
quit;

data 
1 2 1 
2 3 1 
3 5 1 
4 4 1 
5 8 2 
6 6 2 
7 4 2 
8 2 2 
9 2 2

How can I creat new data with only Z=1 and only Z=2 ?

Thank you.

Answer 1

You could use the loc function to subset your data matrix. The following is the description of the function, snipped from Indexing matrices in Introduction to SAS/IML.

the LOC function is often very useful for subsetting vectors and matrices. This function is used for locating elements which meet a given condition. The positions of the elements are returned in row-major order. For vectors, this is simply the position of the element. For matrices, some manipulation is often required in order to use the result of the LOC function as an index. The syntax of the function is:

matrix2=LOC(matrix1=value);

Applied to your example:

proc iml;  
  x={1 2 3 4 5 6 7 8 9};
  y={2,3,5,4,8,6,4,2,2};
  z={1,1,1,1,2,2,2,2,2};
  data=t(x)||y||z;
  print data;
  z1rows=loc(data[,3]= 1);
  z1=data[z1rows,];
  print z1;
  z2rows=loc(data[,3]= 2);
  z2=data[z2rows,];
  print z2;
  run;
quit;

The result for print z1;

+------------+
|     z1     |
+---+----+---+
| 1 |  2 | 1 |
| 2 |  3 | 1 |
| 3 |  5 | 1 |
| 4 |  4 | 1 |
+---+----+---+

The result for print z2;

+------------+
|     z2     |
+---+----+---+
| 5 |  8 | 2 |
| 6 |  6 | 2 |
| 7 |  4 | 2 |
| 8 |  2 | 2 |
| 9 |  2 | 2 |
+---+----+---+