2

A simple example:

If I type #"w" in style "area" how do I get an #"z"? (ex. "qwerty ww" -> "qzerty zz")

noein
  • 411
  • 2
  • 10

2 Answers2

2

As you want the conversion on the fly, you can either modify R3-GUI before loading. So load r3-gui.r3 down to your local directory. Then you add the line if key == #"w" [key: #"z"] to the function do-text-key, so it looks like

do-text-key: funct [
  "Process text face keyboard events."
  face [object!]
  event [event! object!]
  key
] [
  text-key-map/face: face
  text-key-map/shift?: find event/flags 'shift
  if no-edit: not tag-face? face 'edit [
    key: any [select/skip text-key-map/no-edit key 2 key]
  ]
  either char? key [
    if key == #"w" [key: #"z"]
    text-key-map/key: key
    switch/default key bind text-key-map/chars 'event [
      unless no-edit [
          insert-text-face face key
      ]
    ]
  ] [
    if find event/flags 'control [
      key: any [select text-key-map/control key key]
    ]
      text-key-map/key: key
      switch/default key text-key-map/words [return event]
  ]
  none
]

Probably the official way would be to use on-key wih Rebol3

load-gui
view [
  a: area  on-key [ ; arg: event
     if arg/type = 'key [
        if  arg/key == #"w" [arg/key:  #"z"]
     ]
     do-actor/style face 'on-key arg face/style
  ]
]

And finally a way to do this with Rebol2 on the fly

key-event: func [face event] [
    if event/type = 'key [ 
        if all [event/key = #"w"   ] [
            append a/text  #"z" 
            focus a
            view w 
           return false
        ]
    ] 
    event 
] 
insert-event-func :key-event        

view w: layout [
    a: area 
]
sqlab
  • 6,412
  • 1
  • 14
  • 29
  • The replacement must be done while I type. I want to understand how R3Gui (or VID) handles the input and display of characters. – noein Feb 17 '15 at 15:49
  • I added a few ways to get a on the fly conversion – sqlab Feb 18 '15 at 09:11
  • The code for R3 is perfect (Do you think that inserting a string instead of a character is much more complicated ?). – noein Feb 18 '15 at 13:49
  • The code for R2 does not properly handle the caret and appends the character only at the end of the sentence. – noein Feb 18 '15 at 13:50
  • I doubt that inserting a string instead of a char is possible with this method. You would have to use a different way probably along my first propositons with replace. This would also work properly with Rebol2. – sqlab Feb 22 '15 at 16:13
2

After reading some files of r3-gui (text-caret.r3, text-cursor.r3, text-edit.r3, text-keys.r3, text.r3) and the editor, I found a solution that allows me to insert not only a character but also string:

do %r3-gui.r3

insertText-moveCursor-updateFace: func [
    face
    string
    n-move
][
    insert-text-face face string
    move-cursor face 'left n-move false 
    update-text-caret face 
    see-caret face
    show-later face
]   

i-m-u: :insertText-moveCursor-updateFace

view [
    area on-key [
        either arg/type = 'key [
            switch/default  arg/key [
                #"w" [i-m-u face/names/text-box "z" 0]
                #"[" [i-m-u face/names/text-box "[]" 1]
                #"$" [i-m-u face/names/text-box "func [] []" 4]
            ] [
                ;switch/default 
                do-actor/style face 'on-key arg face/style
            ]
        ] [
            ;arg/type != 'key
            do-actor/style face 'on-key arg face/style
        ]   
    ]   
]

Area is a compound styles. It is composed of a text-box and a scroller. They are contained in face/names.

noein
  • 411
  • 2
  • 10