How to correctly error out in JSON parsing with Data.Aeson

Question

My type and correponding FromJSON implementation as listed below.

The nonEmpty turns a List into a Maybe NonEmpty and I'm trying to correctly deal with the case where the List is indeed empty and I have to abort the parsing. This parsing is actually done inside of parseJsonBody, which means I don't want to error "foo" my way out of it, but I want to return mzero (or whatever else will do the trick, mzero is the only thing I've stumbled upon so far) so that the handler correctly returns a 400 instead of crashing with a 500.

The approach below compiles, but as far as I can tell is pretty much equals to error or some other form of exception throwing inside of the parseJSON. If I return mzero however (e.g. with <*> mzero instead of that line), it fails nicely as intended.

import qualified Data.List.NonEmpty as NE
data GSAnswer = GSAnswer { gsAnswerQuestionId :: Int
                         , gsAnswerResponses :: NE.NonEmpty GSResponse
                         } deriving (Show, Eq)


instance FromJSON GSAnswer where
  parseJSON (Object o) =
    GSAnswer <$> o .: "question-id"
             -- how do I return mzero here based on NE.nonEmpty?
             -- this will throw an exception right now on an empty list
             <*> fmap (fromMaybe (fail "foo") . NE.nonEmpty) (o .: "responses")
  parseJSON _ = mzero

One option would be to somehow pattern match on the result of fmap NE.nonEmpty (o .: "responses"), but I can't quite figure out what the pattern would be there: doesn't look like Parser has any constructors?

Zeta · Accepted Answer · 2015-02-14T00:52:44.583

5

Essentially, you need a Parser [a] -> Parser NE.NonEmpty transformer, which is relatively easy:

-- toNonEmptyP :: Parser [a] -> Parser NE.NonEmtpy
toNonEmptyP p = fmap NE.nonEmpty p >>= maybe mzero return

We map NE.nonEmpty on our regular list parser, which gives us Parser (Maybe NE.NonEmpty). We then inspect the Maybe with maybe and either use mzero if it was Nothing, or return the parsed value back to the parsing context. Your FromJSON instance then boils down to

instance FromJSON GSAnswer where
  parseJSON (Object o) =
    GSAnswer <$> o .: "question-id"
             <*> toNonEmptyP (o .: "responses")
  parseJSON _ = mzero

You can use fail msg instead of mzero to provide a custom error message, as fail :: String -> Parser a doesn't bottom out.

edited Feb 14 '15 at 00:52

answered Feb 13 '15 at 07:21

Zeta

103,620
13
194
236

Seems to do the trick, thank you. Any suggestions regarding how to add a specific error message to a Parser failure? Right now the reported error message is "mzero", it'd be neat if I could pass my own error message there for why Parser had to abort. – Alexandr Kurilin Feb 13 '15 at 22:24
Have you tried `fail "msg"` instead of `mzero` in the transformer? I'm currently not at my PC, but I can check later. – Zeta Feb 13 '15 at 22:37
That seems to do the trick, thank you, I altered the above to: toNonEmptyP :: String -> Parser [a] -> Parser (NE.NonEmpty a) toNonEmptyP msg p = fmap NE.nonEmpty p >>= maybe (fail msg) return – Alexandr Kurilin Feb 13 '15 at 23:16

How to correctly error out in JSON parsing with Data.Aeson

1 Answers1