Rewriting a match in Coq

Question

In Coq, suppose I have a fixpoint function f whose matching definition on (g x), and I want to use a hypothesis in the form (g x = ...) in a proof. The following is a minimal working example (in reality f, g would be more complicated):

Definition g (x:nat) := x.

Fixpoint f (x:nat) := 
  match g x with
    | O => O
    | S y => match x with 
      | O => S O
      | S z => f z
      end 
  end.

Lemma test : forall (x : nat), g x = O -> f x = O.
Proof.
  intros.
  unfold f.
  rewrite H. (*fails*)

The message shows where Coq gets stuck:

(fix f (x0 : nat) : nat :=
   match g x0 with
   | 0 => 0
   | S _ => match x0 with
            | 0 => 1
            | S z0 => f z0
            end
   end) x = 0

Error: Found no subterm matching "g x" in the current goal.

But, the commands unfold f. rewrite H. does not work.

How do I get Coq to unfold f and then use H ?

score 5 · Accepted Answer · edited Aug 22 '15 at 07:15

Parameter g: nat -> nat.

(* You could restructure f in one of two ways: *)

(* 1. Use a helper then prove an unrolling lemma: *)

Definition fhelp fhat (x:nat) := 
  match g x with
    | O => O
    | S y => match x with 
      | O => S O
      | S z => fhat z
      end 
  end.

Fixpoint f (x:nat) := fhelp f x.

Lemma funroll : forall x, f x = fhelp f x.
destruct x; simpl; reflexivity.
Qed.

Lemma test : forall (x : nat), g x = O -> f x = O.
Proof.
  intros.
  rewrite funroll.
  unfold fhelp.
  rewrite H.
  reflexivity.
Qed.

(* 2. Use Coq's "Function": *)

Function f2 (x:nat) := 
  match g x with
    | O => O
    | S y => match x with 
      | O => S O
      | S z => f2 z
      end 
  end.

Check f2_equation.

Lemma test2 : forall (x : nat), g x = O -> f2 x = O.
Proof.
  intros.
  rewrite f2_equation.
  rewrite H.
  reflexivity.
Qed.

The issue is that Coq's ``simpl`` (and such like ``unfold, cbv, ...``) usually are too eager to simplify and unfold too much. Stating the rewriting lemma exactly as you need (``funroll`` here) with a really trivial proof, and using this lemma is a bit more complex, but yields better results in general. — Vinz, Feb 09 '15 at 11:03

score 1 · Answer 2 · answered Nov 18 '16 at 22:13

1

I'm not sure if this would solve the general problem, but in your particular case (since g is so simple), this works:

Lemma test : forall (x : nat), g x = O -> f x = O.
Proof.
  unfold g.
  intros ? H. rewrite H. reflexivity.
Qed.

answered Nov 18 '16 at 22:13

Olivier Verdier

46,998
29
98
90

From the question: "(in reality f, g would be more complicated)" – Anton Trunov Nov 19 '16 at 07:55
Yes, I saw that now. But in all honesty, did the OP really submit a minimal working example? :-) – Olivier Verdier Nov 19 '16 at 15:16

score 0 · Answer 3 · answered Sep 16 '18 at 09:21

Here is another solution, but of course for this trivial example. Perhaps will give you some idea. Lemma test2 : forall (x : nat), g x = O -> f x = O.
Proof.
=>intros;
pattern x;
unfold g in H;
rewrite H;
trivial.
Qed.

Rewriting a match in Coq

3 Answers3