get one field from itab with read table TRANSPORTING

Question

I trying to get one field from interal table like this:

READ TABLE tbl_peps TRANSPORTING ususap INTO lv_responsable WITH KEY usr03 = wa_tbl_prps-usr03.

This sentence is wrong, it gives me an error

tbl_peps and lv_responsable are incompatibles

.

Is there a way to achieve that using "transporting fields"?

score 15 · Answer 1 · answered Jan 17 '15 at 14:27

15

With the new syntax (At least ABAP 7.40) you do not need a workarea anymore. The coding for your example would be:

try.
    lv_responsable = tbl_peps[ usr03 = wa_tbl_prps-usr03 ]-ususap.
catch CX_SY_ITAB_LINE_NOT_FOUND.
endtry.

Further info of the new table expressions can be found here.

answered Jan 17 '15 at 14:27

Alexander Jäger

219
1
3

Excellent contribution – funkeeiads Jan 20 '15 at 18:07
@funkeeiads If you think this is an excelltent contribution you can uncheck the accepted mark from the other question and put it here. – Jagger Feb 10 '17 at 09:08

score 5 · Accepted Answer · edited Feb 11 '20 at 16:52

5

According to the ABAP Documentation on READ TABLE, if you use the transporting-option the work area receiving the data must be compatible with the line type of the table you read from. Your declared variable lv_responsable seems to be incompatible with tbl_peps, therefore the error when checking your code.

This should work:

DATA:
  wa_peps like line of tbl_peps.

READ TABLE tbl_peps TRANSPORTING ususap INTO wa_peps WITH KEY usr03 = wa_tbl_prps-usr03.  
MOVE wa_peps-ususap TO lv_responsable.

edited Feb 11 '20 at 16:52

Mike

14,010
29
101
161

answered Jan 08 '15 at 17:36

Dirk Trilsbeek

5,873
2
25
23

1

I wanted to avoid work-area, because only one field is needed. – funkeeiads Jan 08 '15 at 18:04
@Dirk Trilsbeek Are there noticeable benefits of using the TRANSPORTING keyword in the READ TABLE statement. The statement would work with and without it. i.e: READ TABLE tbl_peps INTO wa_peps WITH KEY usr03 = wa_tbl_prps-usr03. move wa_peps-ususap to lv_responsable. – Erik Mar 14 '18 at 10:49
1

@Erik with TRANSPORTING you can chose to transport only a subset of fields into your target structure. For instance if you only want to take a single field and move the value into an already populated work area, keeping the values of other fields in the WA intact. As READ TABLE works on internal tables and is in-memory, I don't think there are any serious performance advantages. Depends of course on the amount of data. – Dirk Trilsbeek Mar 14 '18 at 11:01

score 3 · Answer 3 · answered Feb 09 '17 at 10:45

Solving the underlying problem

The reason you would want to transport only one field is to save memory and speed up processing. There is a better way to do that, use field symbols:

READ TABLE tbl_peps 
  ASSIGNING FIELD-SYMBOL(<fs_responsable>) 
  WITH KEY usr03 = wa_tbl_prps-usr03.

The inline definition only works with ABAP 740 and up, but you can do this in earlier versions:

FIELD-SYMBOLS: <fs_responsable> LIKE LINE OF tbl_peps.
READ TABLE tbl_peps 
  ASSIGNING <fs_responsable> 
  WITH KEY usr03 = wa_tbl_prps-usr03.

score 0 · Answer 4 · answered Jan 08 '15 at 17:38

0

There is no way. Lv_responsable has to be defined as follows.

DATA: lv_responsable LIKE LINE OF tbl_peps.

Only then can you assign the value in field lv_responsable-ususap to another variable of the field type.

answered Jan 08 '15 at 17:38

Jagger

10,350
9
51
93

I am afraid your right .. i thought that there was a way not using a work area. – funkeeiads Jan 08 '15 at 17:54

get one field from itab with read table TRANSPORTING

4 Answers4

Solving the underlying problem