Merge lists of lists in prolog

Question

I would like to perform something like:

merge([[[],[],[],[t1]],[[],[],[],[t2,t3]]], X).

where X would return as: [[],[],[],[t1,t2,t3]].

But I have tried everything to my prolog knowledge and came up with nothing.

Any hints?

Imagine it as:

Computer(
    Tasklist1(
            core1[sometasks],core2[sometasks],...,coreX(sometasks)), 
    ...
    TasklistX(
            core1[sometasks],core2[sometasks],...,coreX(sometasks))
)

so the tasklist after tasklist1 needs to be scheduled on the same cores, after the tasks of tasklist1.

And `[[[1],[2],[3]], [[4],[5],[6]]]` would yield `[[1,4],[2,5],[3,6]]`? — aioobe, Dec 28 '14 at 13:14
yes, indeed! you just 'append' every X'th element of every list — voluminat0, Dec 28 '14 at 13:18
You can imagine that each list that you get is a processor core, and the numbers are tasks. the tasks are wrapped in lists to clarify that those are the tasks for 1 core. — voluminat0, Dec 28 '14 at 13:20
The format of input is always of the following: [ [[],[], ...], [[],[], ...], ... ] and no deeper. Imagine it as in the example of my question, I edited it for you. — voluminat0, Dec 28 '14 at 13:24
So your example of merge([[[1],[2],[3]], [[4],[5],[6]]]) would still yield [[1,4],[2,5],[3,6]]. — voluminat0, Dec 28 '14 at 13:33
Let us [continue this discussion in chat](http://chat.stackoverflow.com/rooms/67789/discussion-between-valentijn-spruyt-and-aioobe). — voluminat0, Dec 28 '14 at 13:36

score 1 · Answer 1 · answered Dec 28 '14 at 15:29

I thought it could be easier...

merge(L, R) :-
    maplist(length_list(N), L),
    findall(S, (
        between(1,N,I),
        findall(Zs, (
            member(Z,L),
            nth1(I,Z,Zs)), T),
        append(T, S)), R).

length_list(Len, L) :- length(L, Len).

lurker · Accepted Answer · 2014-12-30T12:43:48.343

It's not totally clear what the limits of the problem may be. But here is a solution which assumes you may have more than two inner list-of-lists, and the count of the innermost lists might vary.

merge2(L, [], L) :- L \= [].
merge2([], L, L).
merge2([LH1|LT1], [LH2|LT2], [LH3|LT3]) :-
    append(LH1, LH2, LH3),
    merge2(LT1, LT2, LT3).

merge([L], L).
merge([H1,H2|T], R) :-
    merge2(H1, H2, H),
    merge([H|T], R).

So,

| ?- merge([[[],[],[],[t1]],[[],[],[],[t2,t3]]], L).

L = [[],[],[],[t1,t2,t3]] ? ;

no
| ?- merge([[[1],[2],[3]], [[4],[5],[6]],[[a],[b],[c,d]]], L).

L = [[1,4,a],[2,5,b],[3,6,c,d]] ? a

no
| ?- merge([[[1],[2],[3]], [[5],[6]],[[a],[b],[c,d]]], L).

L = [[1,5,a],[2,6,b],[3,c,d]] ? ;

(1 ms) no
| ?-

If you want to restrict the innermost list counts to be the same, you can replace merge2 with maplist, and the merge predicate simply becomes:

merge([L], L).
merge([H1,H2|T], R) :-
    maplist(append, H1, H2, H),
    merge([H|T], R).

Thanks! This is what I was looking for. sorry for the late reply — voluminat0, Dec 30 '14 at 09:41
@ValentijnSpruyt no worries. You can also simplify the solution using `maplist` if inner list counts are the same, per my edited answer. — lurker, Dec 30 '14 at 12:45

Merge lists of lists in prolog

2 Answers2