Unable to match pattern using XSLT

Question

I've below XML.

<?xml version="1.0" encoding="UTF-8"?>
<list>
  <list.item>
    <label>(1)</label> This is first list item)
  </list.item>
  <list.item><label>
    <star.page>179</star.page> (2)</label>This is second)
  </list.item>
  <list.item><label>(3)</label>This is third)</list.item>
</list>

here my aim is. If there is star.page, i want to break the blocks and recreate it. I mean. If the star.page is inside list\list.item\label, i want to close them in the order list.item\list print star.page and recreate the list as list\list.item i'm using the below XSLT.

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output method="html" doctype-public="XSLT-compat" omit-xml-declaration="yes" encoding="UTF-8" indent="yes" />

    <xsl:template match="/">
      <hmtl>
        <head>
          <title>New Version!</title>
        </head>
        <xsl:apply-templates/>
      </hmtl>
    </xsl:template>


    <xsl:template name="orderedlist" match="list">
      <ol class="eng-orderedlist orderedlist">
        <xsl:apply-templates/>
      </ol>
    </xsl:template>

    <xsl:template name="orderitem" match="list.item">
      <xsl:apply-templates select="./label/*[1][self::star.page]"/>
      <li class="item">
        <div class="para">
          <xsl:if test="./label">
            <span class="item-num">
              <xsl:value-of select="./label/text()"/>
            </span>
          </xsl:if>
          <xsl:choose>
            <xsl:when test="./node()">
              <xsl:apply-templates select="child::node()[not(self::label)]"/>
            </xsl:when>
            <xsl:otherwise>
              <xsl:text>&#160;</xsl:text>
            </xsl:otherwise>
          </xsl:choose>
        </div>
      </li>
    </xsl:template>


    <xsl:template match="star.page">
      <xsl:choose>
        <xsl:when test="../../..[list] and ..[label]">
          <xsl:text disable-output-escaping="yes"><![CDATA[</ol>]]></xsl:text>
          <xsl:call-template name="runn_head"/>
          <xsl:text disable-output-escaping="yes"><![CDATA[<ol class="eng-orderedlist orderedlist">]]></xsl:text>
        </xsl:when>
        <xsl:otherwise>
          <xsl:call-template name="runn_head"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:template>


    <xsl:template name="runn_head">
      <div class="x">
        <xsl:value-of select="."/>
      </div>
    </xsl:template>
</xsl:transform>

My current output is

<hmtl>
   <head>
      <meta http-equiv="Content-Type" content="text/html; charset=UTF-8">
      <title>New Version!</title>
   </head>
   <ol class="eng-orderedlist orderedlist">

      <li class="item">
        <div class="para">
          <span class="item-num">(1)</span>This is first list item)
        </div>
      </li>

      <div class="x">179</div>

      <li class="item">
        <div class="para">
          <span class="item-num">(2)</span>This is second)
        </div>
      </li>     
      <li class="item">
        <div class="para">
          <span class="item-num">(3)</span>This is third)
        </div>
      </li>     
   </ol>
</hmtl>

but my Expected output is

<hmtl>
   <head>
      <meta http-equiv="Content-Type" content="text/html; charset=UTF-8">
      <title>New Version!</title>
   </head>
   <ol class="eng-orderedlist orderedlist">
     <li class="item">
       <div class="para">
         <span class="item-num">(1)</span>This is first list item)
       </div>
     </li>
   </ol>

   <div class="x">179</div>

   <ol class="eng-orderedlist orderedlist">
     <li class="item">
       <div class="para">
         <span class="item-num">(2)</span>This is second)
       </div>
     </li>

     <li class="item">
       <div class="para">
         <span class="item-num">(3)</span>This is third)
       </div>
     </li>
   </ol>
</hmtl>

in the expected output above div class="x", you can see that <ol> is closed and after printing div class="x", it is reopened (<ol class="eng-orderedlist orderedlist">), please let me know where am i going wrong and how to fix it.

Here is the working demo

Demo

So whenever you encounter star.page you want the ol tag to be closed and opened again? and star.page will always appear inside label? — Rnet, Dec 24 '14 at 09:09

Rnet · Accepted Answer · 2014-12-24T10:27:46.307

If <star.page> will be under label, then you don't need to even have the xsl:choose. Although this xslt can be written in a much more cleaner and efficient way, this would be the minimal change to make it work as of now:

<xsl:template match="star.page">
    <xsl:choose>
        <xsl:when test="name(..) = 'label' and name(../../..) = 'list' ">

EDIT 1: While the above change will work, you could always rewrite the whole thing in a much more cleaner way like this:

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="html" doctype-public="XSLT-compat" omit-xml-declaration="yes"
        encoding="UTF-8" indent="yes"/>

    <xsl:template match="/">
        <hmtl>
            <head>
                <title>New Version!</title>
            </head>
            <xsl:apply-templates/>
        </hmtl>
    </xsl:template>

    <xsl:template name="orderedlist" match="list">
        <ol class="eng-orderedlist orderedlist">
            <xsl:apply-templates select="list.item"/>
        </ol>
    </xsl:template>

    <xsl:template name="orderitem" match="list.item">
        <xsl:apply-templates select="label/star.page"/>
        <li class="item">
            <div class="para">
                <span class="item-num">
                   <xsl:for-each select="label/text()">
                       <xsl:value-of select="."/>
                   </xsl:for-each>
                </span>
                <xsl:for-each select="text()">
                   <xsl:value-of select="."/>
                </xsl:for-each>
            </div>
        </li>
    </xsl:template>

    <xsl:template match="label/star.page">
        <xsl:text disable-output-escaping="yes">&lt;/ol&gt;</xsl:text>
        <div class="x">
            <xsl:value-of select="."/>
        </div>
        <xsl:text disable-output-escaping="yes">&lt;ol class="eng-orderedlist orderedlist"&gt;</xsl:text>
    </xsl:template>

</xsl:transform>

Edit2: updated to include all text nodes of label

Hi Rnet, thanks for the solution, i'm using this `choose` since there are similar many different nodes to be matched and based on that i need to close the corresponding parent. — user3872094, Dec 24 '14 at 09:52
Just a small doubt, i want to know what `..[label]` means, i understood `name()`, doesn't `..[label]` work? if i need to use that type, how to. I'm asking this because i want to match `nested lists` Thanks — user3872094, Dec 24 '14 at 09:54
@user3872094 `..[label]` does not work because `..` refers to label itself, and you would be searching for `label` in `label` which would always yield false, so you would need to climb up a node higher and then search for label; `../..[label]` will work. With `name(..)` you just save a step. — Rnet, Dec 24 '14 at 10:11

Unable to match pattern using XSLT

1 Answers1