-1

I have some problem with my code here. Let's say I have a knowledge base like this:

university('University of Cambridge', 1, 'United Kingdom', 90.3, 92.8, 89.4).
university('University of Oxford', 2, 'United Kingdom', 88.9, 94.8, 88.0).
university('ETH Zurich - Swiss Federal Institute of Technology', 3, 'Switzerland', 86.4, 94.4, 92.2).
university('University of Edinburgh', 4, 'United Kingdom', 83.7, 88.8, 83.6).

Then I call it out like this: (Ignore the checkC(Country)/checkC(_))

checkC(Country):-
    university(U, R, Country, _, _, _),nl,
    write('University: '),write(U),nl,
    write('Rank: '),write(R),nl,
    write('Country: '),write(Country),nl,
    fail; true, nl,
    write('************'), nl,nl.

checkC(_):-
    write('Country not found'),nl,nl.

My question is, why is it if the user inputs a random country name not within the knowledge base, the write('Country not found') won't come out, I found out that it has something to do with the fail; true.

Any help?

false
  • 10,264
  • 13
  • 101
  • 209
Huxley
  • 1
  • 6

1 Answers1

2

While the fail; true trick is nice for the command line, gathering multiple solutions is usually done via the predicates findall, bagof and setof.

I used format for readabilities sake.

checkC(X):-
    findall( [U,R,X], university(U,R,X,_,_,_), List),
    (List = [] -> 
     write('Country not found\n\n');
     writeCountries(List)).

writeCountries([]).
writeCountries([X|R]):-
    writeCountries(R),
    format('University: ~w~nRank: ~w~nCountry: ~w~n~n',X).

If you are using swipl, maplist comes in handy: 

checkC(X):-
    findall( [U,R,X], university(U,R,X,_,_,_), List),
    (List = [] -> 
     write('Country not found\n\n');
     maplist(format('University: ~w~nRank: ~w~nCountry: ~w~n~n'),List)).

If you don't have format/2 look if you have writef/2 or printf/2.

Patrick J. S.
  • 2,885
  • 19
  • 26
  • Hi again, is there a way to sort the list in ascending order according to the rank, because right now it shows as descending order. – Huxley Dec 05 '14 at 01:27
  • Sure. Either use `sort/2` and have the rank first, you'll then have to work with positional arguments in the `format` call. Or write a comparison predicate and call `predsort/3`. If you're sure that the clauses are sorted by rank in the database, you also can switch the two lines in the clause body of the `writeCountries` predicate. – Patrick J. S. Dec 05 '14 at 04:31