Create consecutive ID based on non-consecutive ID in Stata

Question

Given the following variables (id and partner) in Stata, I would like to create a new variable (pid) that is simply the consecutive partner counter within id (as you can see, partner is not consecutive). Here is a MWE:

clear
input   id  partner pid
        1   1       1
        1   1       1
        1   3       2
        1   3       2
        2   2       1
        2   3       2
        2   3       2
        2   3       2
        2   5       3
        2   5       3
end

score 2 · Accepted Answer · answered Oct 13 '14 at 11:27

2

// create example data
clear
input   id  partner
        1   1      
        1   1      
        1   3      
        1   3     
        2   2     
        2   3     
        2   3     
        2   3     
        2   5     
        2   5     
end

// create pid
bysort id partner : gen pid = _n == 1
by id : replace pid = sum(pid)

// admire the result
list, sepby(id)

answered Oct 13 '14 at 11:27

Maarten Buis

2,684
12
17

3

Another way to do it: `bysort id (partner) : gen pid = sum(partner != partner[_n-1])` – Nick Cox Oct 13 '14 at 11:32
Thanks a lot, Maarten! I will wait for a few minutes and then accept your answer. – Bernd Weiss Oct 13 '14 at 11:45

Create consecutive ID based on non-consecutive ID in Stata

1 Answers1