Autodesk Inventor VBA Scripting

Question

I'm trying to connect two solid model profiles in Autodesk Inventor using VBA scripting. I came as far as drawing the 3D lines which are supposed to act as profiles later on. After the script has finished drawing, I can select the two loops and connect them using the loft operation through the GUI. I'm thinking that should be possible from the script, too, I just can't figure out how. Here's my script so far:

Sub loft()

  Set oDoc = ThisApplication.Documents.Add(kPartDocumentObject, , True)
  Set oPartDef = oDoc.ComponentDefinition

  Dim osketch3D As Sketch3D
  Set osketch3D = oPartDef.Sketches3D.Add()

  Set oTG = ThisApplication.TransientGeometry
  Dim wire(198) As SketchLine3D

  Set wire(0) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(0, 0, 0), oTG.CreatePoint(10, 0, 0))
  Set wire(1) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(10, 0, 0), oTG.CreatePoint(10, 10, 1))
  Set wire(2) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(10, 10, 1), oTG.CreatePoint(0, 10, 0))
  Set wire(3) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(0, 10, 0), oTG.CreatePoint(0, 0, 0))

  Set wire(4) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(0, 0, 5), oTG.CreatePoint(10, 0, 5))
  Set wire(5) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(10, 0, 5), oTG.CreatePoint(10, 10, 5))
  Set wire(6) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(10, 10, 5), oTG.CreatePoint(0, 10, 5))
  Set wire(7) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(0, 10, 5), oTG.CreatePoint(0, 0, 5))

' .....    
' Select wires 0-3 and 4-7 as profiles, put them in an object collection and call the loft op.

End Sub

J-SHould · Answer 1 · 2015-08-26T17:19:14.100

Sub loft()

    'Declare PartDocument to activate Intellisense
    Dim oDoc As PartDocument

    Set oDoc = ThisApplication.Documents.Add(kPartDocumentObject, , True)
    Set oPartDef = oDoc.ComponentDefinition

    Dim osketch3D As Sketch3D
    Set osketch3D = oPartDef.Sketches3D.Add()

    Set oTG = ThisApplication.TransientGeometry
    Dim wire(198) As SketchLine3D

    Set wire(0) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(0, 0, 0), oTG.CreatePoint(10, 0, 0))
    Set wire(1) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(10, 0, 0), oTG.CreatePoint(10, 10, 1))
    Set wire(2) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(10, 10, 1), oTG.CreatePoint(0, 10, 0))
    Set wire(3) = osketch3D.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(0, 10, 0), oTG.CreatePoint(0, 0, 0))

    'Declare Profile3D to regroup wires.
    Dim oProfile1 As Profile3D
    Set oProfile1 = osketch3D.Profiles3D.AddOpen

    'Declare another sketch to be able to catch 2 differents profiles.
    Dim osketch3D2 As Sketch3D
    Set osketch3D2 = oPartDef.Sketches3D.Add()

    Set wire(4) = osketch3D2.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(0, 0, 5), oTG.CreatePoint(10, 0, 5))
    Set wire(5) = osketch3D2.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(10, 0, 5), oTG.CreatePoint(10, 10, 5))
    Set wire(6) = osketch3D2.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(10, 10, 5), oTG.CreatePoint(0, 10, 5))
    Set wire(7) = osketch3D2.SketchLines3D().AddByTwoPoints(oTG.CreatePoint(0, 10, 5), oTG.CreatePoint(0, 0, 5))

    'Declare second Profile3D to regroup wires.
    Dim oProfile2 As Profile3D
    Set oProfile2 = osketch3D2.Profiles3D.AddOpen

    'Create object collection need by Inventor functions.
    Dim oCollection As ObjectCollection
    Set oCollection = ThisApplication.TransientObjects.CreateObjectCollection

    'Add profiles to collection.
    oCollection.Add oProfile1
    oCollection.Add oProfile2

    'Create loft definition needed by Loft function.
    Dim oLoftDef As LoftDefinition
    Set oLoftDef = oDoc.ComponentDefinition.Features.LoftFeatures.CreateLoftDefinition(oCollection, kSurfaceOperation)

    'Creating loft.
    Dim oLoftFeat As LoftFeature
    Set oLoftFeat = oDoc.ComponentDefinition.Features.LoftFeatures.Add(oLoftDef)



End Sub

You should comment the parts of the code that are changed and mention why it solves the problem. — Nathaniel Ford, Aug 26 '15 at 16:32
I guess it could clarify things, but this solution is pretty simple so I did not believe there was place for comments. Since you point it out, I will now modify my answer. — J-SHould, Aug 26 '15 at 17:09

Autodesk Inventor VBA Scripting

1 Answers1