How do I listen for a keystroke in batch

Question

I need my code to loop through a subroutine until a key is pressed. I have no idea how to do this. Any help?

Answer 1

you could use the timeout and default extension for the Choice command EX:

:start
@echo off
cls
:loop1 
cls
echo press 1 for option 1 
echo press 2 for option 2 
echo press 3 for option 3 
echo press any other number key to tell the date
echo.
echo %time%
choice /t 1 /c 123456789q /d q >nul
if %errorlevel% EQU 10 goto loop1
if %errorlevel% EQU 1 goto 1
if %errorlevel% EQU 2 goto 2
if %errorlevel% EQU 3 goto 3
if %errorlevel% GEQ 4 goto end
goto loop1
:1
echo.
echo.
echo option 1 
echo.
pause 
exit 
:2
echo.
echo.
echo option 2
echo.
pause 
exit 
:3
echo.
echo.
echo option 3
echo.
pause 
exit 
:end
echo %date%
pause
Exit

in this case the Choice command is automatically selecting Q as the default choice every 1 second so if the user typed Q it'll just skip 1 second in the loop. However if they type any number key besides 1, 2, 3 the program will tell the date. if the user types 1 the program will do option 1 and same for 2 and 3 any other key won't do anything. The only downside is you have to wait 1 second max and you have to reserve one key for the loop

Answer 2

Or you can just type this:

@echo off
color 0a
title KeyStrokeSim
goto Start

:Start
cls
echo Press D or F to continue...
choice /c df /n
if %errorlevel%==1 goto Finished
if %errorlevel%==2 goto Finished

:Finished
echo You have Pressed D or F!
pause
goto Start

Answer 3

Late answer, but DOES NOT use choice or SET /P, but replace instead.
This is the idea:

@echo off
SETLOCAL EnableDelayedExpansion
echo Press any key...

>keystroke.txt replace ? . /u /w
FOR /F delims^=^ eol^= %%K in (
'2^>nul findstr /R "^" "keystroke.txt"'
) do set "key=%%K"

del /f /q "keystroke.txt"
echo You pressed: [!key!]

The script takes advantage of the /W option of REPLACE.

Edit: Now supports ; (default eol)

Answer 4

You could try this:

Stroke.bat

@echo off
Echo. > Temp.txt
:: You require choice.exe for this
choice /c 1234567890qwertyuiopasdfghjklzxcvbnm
Echo 1 > Temp.txt

Main.bat

@echo off
set var=
:: Code Prior to Loop


:: Loop starts below
start /b stroke.bat
:loop

::: Loop Code Goes here
:: 
:: You will not be able to take user-input in loop
:: Do not tamper with "var"
:: To force exit the loop just "goto end"
:: Note if you force exit the loop you will need to exit this bat
::   and start a new window (since Stroke will be running)
::
::: End of loop

<Temp.txt set /p var=
if "%var%" NEQ "1" goto loop
:end

:: Post loop code
Exit

And that should work with any Character or Number, but not punctuation or Enter, Space etc.

You could modify this to work only for enter by replacing choice with set /p:

@echo off
Echo. > Temp.txt
set /p v=
Echo 1 > Temp.txt

Which you can use for enter and if you do not have choice.exe

Answer 5

If you wish to define a default action if no key is pressed within a certain time, you can use choice as follows to define a keypress:

@Echo off
:ExampleLoop
    Echo.[A] Action [B] Alternate Action
    For /F "delims=" %%C in ('Choice /T 10 /N /C:ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789 /D B') Do (
        CLS & Set "Choice=%%C" & Call :Choice[1-%%C] || (CLS & Echo. %%C is not a valid Choice)
    )
Goto :ExampleLoop

:Choice[1-A]
    Echo %~0
    Echo Elective Command
Exit /B 0
:Choice[1-B]
    ECHO %~0
    Echo Default Command
Exit /B 0

The above will return the literal key as opposed to the ErrorLevel (Note: will return all letters as upper case).

By using call with :Label subroutines, and defining all choice options, the annoying errortone can be avoided and a custom message output through the use of || conditional testing on the Call Outcome. The Label approach also avoids the need for complicated and typically messy conditional testing when multiple options are present.