How can I return the entire contents of a split line based on a search?

Question

I posted previously about a small script that I'm working on. I eventually figured out that problem. Now I'm running into a different one. Hopefully you can help.

Some setup: I have a short list stored as a markdown file.

|One Hundred Years of Solitude|Gabriel García Márquez|-|-|-|-|1967|
|Moby-Dick|Herman Melville|-|-|-|-|1851|
|Frankenstein|Mary Shelley|-|-|-|-|1818|
|On the Road|Jack Kerouac|-|-|-|-|1957|
|The Turn of the Screw|Henry James|-|-|-|-|-|

I've figured out how to feed the file through cat, sed, xargs, and awk.

cat list.md | sed -e 's/^\|//' -e 's/\|$//' -e 's/^ *//' \
-e '/^\:/d' -e '/\'Title'/d' -e '/^\r/d' -e '/^$/d' | xargs -0 echo | \
awk -F '|' '{print "----"} {print "Title:", $1} {print "Author:", $2} \
{print "Date Begun:", $4} {print "Date Finished:", $5}'

That command returns this:

----
Title: One Hundred Years of Solitude
Author: Gabriel García Márquez
Date Begun: -
Date Finished: -
----
Title: Moby-Dick
Author: Herman Melville
Date Begun: -
Date Finished: -
----
Title: Frankenstein
Author: Mary Shelley
Date Begun: -
Date Finished: -
----
Title: On the Road
Author: Jack Kerouac
Date Begun: -
Date Finished: -
----
Title: The Turn of the Screw
Author: Henry James
Date Begun: -
Date Finished: -

What I'd like to do is incorporate this into a script that I can run with an argument like 'books Melville' that will run the above commands, pipe it into grep, search for the argument (preferably either a word or a string), and then return the entire line. As in, if I type 'books Melville', the script would return

----
Title: Moby-Dick
Author: Herman Melville
Date Begun: -
Date Finished: -

Currently, if I type 'books Melville', all that it returns is 'Author: Herman Melville'.

Sorry for the long post.

Edit with another apology: I forgot to mention that I'm on OSX.

Answer 1

I will give you two small awk scripts (will require GNU awk for second script due to multi-char RS. You can make it portable by just using space instead of ---- and use awk paragraph mode). The first script is to remove all that mess you have and create a database file.

$ cat md.file
|One Hundred Years of Solitude|Gabriel García Márquez|-|-|-|-|1967|
|Moby-Dick|Herman Melville|-|-|-|-|1851|
|Frankenstein|Mary Shelley|-|-|-|-|1818|
|On the Road|Jack Kerouac|-|-|-|-|1957|
|The Turn of the Screw|Henry James|-|-|-|-|-|

$ awk -F"[|]" '{
    printf "----\nTitle: %s\nAuthor: %s\nDate Begun: %s\nDate Finished: %s\n", $2, $3, $5, $6
  }' md.file > database.file

Now the database.file looks like this:

----
Title: One Hundred Years of Solitude
Author: Gabriel García Márquez
Date Begun: -
Date Finished: -
----
Title: Moby-Dick
Author: Herman Melville
Date Begun: -
Date Finished: -
----
Title: Frankenstein
Author: Mary Shelley
Date Begun: -
Date Finished: -
----
Title: On the Road
Author: Jack Kerouac
Date Begun: -
Date Finished: -
----
Title: The Turn of the Screw
Author: Henry James
Date Begun: -
Date Finished: -

Once the file is ready, you can use the following awk script probably in a bash script or from command line, which ever way you deem fit.

If you wish to run from bash file, you can create a bash variable that you want to search one.

$ look=Melville
$ echo "$look"
Melville
$ awk -v RS="----" -vlook="$look" '$0~look' database.file

Title: Moby-Dick
Author: Herman Melville
Date Begun: -
Date Finished: -

If you wish to by-pass the shell variable, you can just do a regex search.

awk -v RS="----" '/Melville/' database.file

awk will do the printing for you if your condition is true. Which means, the above statements is exactly like saying

awk -v RS="----" '/Melville/ { print $0 }' database.file

or

awk -v RS="----" -vlook="$look" '$0~look { print $0 }' database.file

Answer 2

With bash:

seek=he
labels=(- Title Author - "Date Begun" "Date Finished")
while IFS='|' read -ra fields; do
    [[ "${fields[*]}" == *"$seek"* ]] || continue
    printf "%s\n" "----"
    for i in 1 2 4 5; do
        printf "%s: %s\n" "${labels[i]}" "${fields[i]}"
    done
done < list.md

----
Title: Frankenstein
Author: Mary Shelley
Date Begun: -
Date Finished: -
----
Title: On the Road
Author: Jack Kerouac
Date Begun: -
Date Finished: -
----
Title: The Turn of the Screw
Author: Henry James
Date Begun: -
Date Finished: -

Answer 3

Using Awk:

#!/usr/bin/awk -f
BEGIN {
    if (!(ARGC >= 2)) exit
    search = ARGV[1]
    ARGV[1] = "/complete/path/to/list.md"
    FS = "|"
    OFS = "\n"
}
$0 ~ search {
    print "----", "Title: " $2, "Author: " $3, "Date Begun: " $4, "Date Finished: " $5
}

Change the value "/complete/path/to/list.md" with a real one. Save it on a directory covered by $PATH like /usr/local/bin and name it as books. Change its permission to 0755 then test it with books Melv.

If you're not running as root, to make it easier, save it first to a temporary file like script.awk, make some proper edits, then run:

sudo install -m 0755 script.awk /usr/local/bin/books

Multiple keywords

This version allows multiple keywords to validate the search:

#!/usr/bin/awk -f
BEGIN {
    if (!(ARGC >= 2)) exit
    for (i = 1; i < ARGC; ++i) {
        keywords[k++] = ARGV[i]
    }
    ARGV[1] = "/complete/path/to/list.md"
    ARGC = 2
    FS = "|"
    OFS = "\n"
}
$0 ~ keywords[0] {
    for (i = 1; i < k; ++i) {
        if (!($0 ~ keywords[i])) {
            next
        }
    }
    print "----", "Title: " $2, "Author: " $3, "Date Begun: " $4, "Date Finished: " $5
}